模式匹配-OCaml:在另一个模式中匹配表达式

Question

我目前正在使用OCaml进行一个小项目；一个简单的数学表达式简化器。我应该在表达式中找到某些模式，并对它们进行简化，以减少表达式中括号的数量。到目前为止，我已经能够实现除两个规则之外的大多数规则，为此我决定创建一个递归的、模式匹配的"filter"函数。我需要执行的两条规则是：

-将所有形式为a-（b+c）或类似形式的表达式转换为a-b-c

-将a/（b*c）或类似形式的所有表达式转换为a/b/c

我怀疑这会相当简单，一旦我成功地实现了一个，我就可以轻松地实现另一个。但是，我在递归模式匹配函数方面遇到了问题。我的类型表达式是：

type expr =
 | Var of string            (* variable *)
 | Sum of expr * expr       (* sum  *)
 | Diff of expr * expr      (* difference *)
 | Prod of expr * expr      (* product *)
 | Quot of expr * expr      (* quotient *)
;;

我主要遇到的问题是比赛中的表情。例如，我正在尝试这样的东西：

let rec filter exp =   
    match exp with       
    | Var v -> Var v                        
    | Sum(e1, e2) -> Sum(e1, e2)          
    | Prod(e1, e2) -> Prod(e1, e2)
    | Diff(e1, e2) ->
        match e2 with
        | Sum(e3, e4) -> filter (diffRule e2)
        | Diff(e3, e4) -> filter (diffRule e2)      
        | _ -> filter e2         
    | Quot(e1, e2) ->                                 ***this line***
        match e2 with  
        | Quot(e3, e4) -> filter (quotRule e2)        
        | Prod(e3, e4) -> filter (quotRule e2)        
        | _ -> filter e2
;;

然而，标记线上的匹配表达式似乎被识别为前一个"内部匹配"的一部分，而不是"主匹配"，因此所有"Quot（…）"表达式永远不会被识别。是否有可能在其他类似的匹配表达式中包含匹配表达式？结束内线比赛的正确方式是什么，这样我就可以继续匹配其他可能性了？

忽略逻辑，因为这几乎是我首先想到的，只是我一直没能尝试，因为我必须首先处理这个"匹配"错误，尽管任何关于如何处理递归性或逻辑的建议都是受欢迎的。

Answer 1

快速解决方案

您只需要在内部匹配项周围添加括号或begin/end

let rec filter exp =
    match exp with
    | Var v -> Var v
    | Sum (e1, e2) -> Sum (e1, e2)
    | Prod (e1, e2) -> Prod (e1, e2)
    | Diff (e1, e2) ->
            (match e2 with
             | Sum (e3, e4) -> filter (diffRule e2)
             | Diff (e3, e4) -> filter (diffRule e2)
             | _ -> filter e2)
    | Quot (e1, e2) ->
            (match e2 with
             | Quot (e3, e4) -> filter (quotRule e2)
             | Prod (e3, e4) -> filter (quotRule e2)
             | _ -> filter e2)
;;

简化

在您的特定情况下，不需要嵌套匹配。你可以使用更大的图案。您还可以使用"；CCD_ 3"；（"或"）图案：

let rec filter exp =
    match exp with
    | Var v -> Var v
    | Sum (e1, e2) -> Sum (e1, e2)
    | Prod (e1, e2) -> Prod (e1, e2)
    | Diff (e1, (Sum (e3, e4) | Diff (e3, e4) as e2)) -> filter (diffRule e2)
    | Diff (e1, e2) -> filter e2
    | Quot (e1, (Quot (e3, e4) | Prod (e3, e4) as e2)) -> filter (quotRule e2)
    | Quot (e1, e2) -> filter e2
;;

通过用_（下划线）替换未使用的模式变量，可以使其更加可读。这也适用于整个子模式，如(e3,e4)元组：

let rec filter exp =
    match exp with
    | Var v -> Var v
    | Sum (e1, e2) -> Sum (e1, e2)
    | Prod (e1, e2) -> Prod (e1, e2)
    | Diff (_, (Sum _ | Diff _ as e2)) -> filter (diffRule e2)
    | Diff (_, e2) -> filter e2
    | Quot (_, (Quot _ | Prod _ as e2)) -> filter (quotRule e2)
    | Quot (_, e2) -> filter e2
;;

以同样的方式，您可以继续简化。例如，前三种情况（Var、Sum、Prod）未经修改地返回，您可以直接表示：

let rec filter exp =
    match exp with
    | Var _ | Sum _ | Prod _ as e -> e
    | Diff (_, (Sum _ | Diff _ as e2)) -> filter (diffRule e2)
    | Diff (_, e2) -> filter e2
    | Quot (_, (Quot _ | Prod _ as e2)) -> filter (quotRule e2)
    | Quot (_, e2) -> filter e2
;;

最后，您可以用e替换e2，用function快捷键替换match：

let rec filter = function
    | Var _ | Sum _ | Prod _ as e -> e
    | Diff (_, (Sum _ | Diff _ as e)) -> filter (diffRule e)
    | Diff (_, e) -> filter e
    | Quot (_, (Quot _ | Prod _ as e)) -> filter (quotRule e)
    | Quot (_, e) -> filter e
;;

OCaml的模式语法很好，不是吗？

Answer 2

您可以通过明智地使用下划线、as和/或模式来使其简洁（我认为更清晰）。生成的代码也更高效，因为它分配更少的（在Var、Sum和Prod的情况下）

let rec filter = function
| Var _ | Sum _ | Prod _ as e -> e
| Diff (_, (Sum _ | Diff _) as e) -> filter (diffRule e)
| Diff (_,e) -> e
| Quot (_, (Quot _| Prod _) as e) -> filter (quoteRule e)
| Quot (_,e) -> filter e
;;