如何计算Erlang中函数调用的数量

Question

我在Erlang服务器上有一个函数，它将数据发布到web服务。这个web服务需要计数器(它被调用了多少次)。我真的不知道他们为什么需要它，但这很重要。

由于某些原因，我不能使用外部DB。所以我需要在服务器上永久存储一些全局变量。我想把计数器保存到一个文件中，每次调用函数时提取并增加它。

有更有效的方法来实现我的目标吗?

编辑该函数可以同时从许多不同的客户端调用，所以这增加了另一个问题:如果3个客户端同时调用该函数，函数将只增加计数器一次，我会得到一个错误。如何使函数等待另一个函数完成，然后执行?

Answer 1

如果3个客户端同时调用函数，函数将只增加计数器一次，我会得到一个错误。如何使函数等待另一个函数完成，然后执行?

我将使用一个用gen_server构建的简单计数器，并且只从它访问磁盘上的计数器。使用这样的gen_server将确保您永远不会遇到文件访问竞争条件。

这里有一些东西可以让你开始:

-module(file_counter).
-export([start_link/0, start/0, increment/0]).
-behaviour(gen_server).
-export([init/1, handle_call/3, handle_cast/2, handle_info/2, terminate/2, code_change/3]).
start_link() ->
    gen_server:start_link({local, ?MODULE}, ?MODULE, [], []).
start() ->
    gen_server:start({local, ?MODULE}, ?MODULE, [], []).
increment() ->
    gen_server:call(?MODULE, increment).
init([]) ->
    {ok, "file_counter.txt"}.
handle_call(increment, _From, File) ->
    Counter = case file:read_file(File) of
        {ok, Binary} -> binary_to_integer(Binary);
        {error, enoent} -> 0
    end,
    ok = file:write_file(File, integer_to_binary(Counter + 1)),
    {reply, Counter, File}.
handle_cast(_Req, State) ->
    {noreply, State}.
handle_info(_Info, State) ->
    {noreply, State}.
terminate(_Reason, _State) ->
    ok.
code_change(_OldVsn, State, _Extra) ->
    {ok, State}.

演示:

1> c(file_counter).
{ok,file_counter}
2> file_counter:start_link().
{ok,<0.40.0>}
3> file_counter:increment().
0
4> file_counter:increment().
1
5> file_counter:increment().
2
6> [ spawn_link(file_counter, increment, []) || _ <- lists:seq(1, 9998) ].
[<0.45.0>,<0.46.0>,<0.47.0>,<0.48.0>,<0.49.0>,<0.50.0>,
 <0.51.0>,<0.52.0>,<0.53.0>,<0.54.0>,<0.55.0>,<0.56.0>,
 <0.57.0>,<0.58.0>,<0.59.0>,<0.60.0>,<0.61.0>,<0.62.0>,
 <0.63.0>,<0.64.0>,<0.65.0>,<0.66.0>,<0.67.0>,<0.68.0>,
 <0.69.0>,<0.70.0>,<0.71.0>,<0.72.0>,<0.73.0>|...]
7> file_counter:increment().
10001

在每次调用之前调用file_counter:increment()，并使用它返回的值作为计数。

编辑:这只是我写的一个快速模块。您可能应该通过将文件名传递给start、start_link和init使其可配置，如果您希望能够运行计数器的多个副本，则不应该使用名称注册进程。这里的代码是一个真正的POC，让你开始。

(在使用SSD磁盘的系统上，我能够每秒执行file_counter:increment()大约5000次)