使用XSLT1.0可以根据一些标准按顺序将XML元素分组到存储桶中

假设我有一些XML要转换为HTML。XML分为有序的部分：

<?xml version="1.0" encoding="utf-8"?>
<root>
  <section attr="someCriteria">
    <h1>Title 1</h1>
    <p>paragraph 1-1</p>
    <p>paragraph 1-2</p>
  </section>
  <section attr="someOtherCriteria">
    <h3>Subtitle 2</h3>
    <ul>
      <li>list item 2-1</li>
      <li>list item 2-2</li>
      <li>list item 2-3</li>
      <li>list item 2-4</li>
    </ul>
  </section>
  <section attr="anotherSetOfCriteria">
    <warning>
      Warning: This product could kill you
    </warning>
  </section>
  <section attr="evenMoreCriteria">
    <disclaimer>
      You were warned
    </disclaimer>
  </section>
  <section attr="criteriaSupreme">
    <p>Copyright 1999-2011</p>
  </section>
</root>

我有几个这样的XML文档。我需要根据标准对这些部分进行分组和转换。将会有两种不同的水桶。

因此，第一部分将在铲斗（例如<div class="FormatOne"></div>）
如果第二部分符合符合"FormatOne"存储桶的条件也会放在这个桶里
如果第三部分需要不同的bucket（例如<div class="FormatTwo"></div>），然后bucket已创建并分区里面的东西都放在这个桶里了
如果第四部分的bucket需要"FormatOne"（与以前的格式不同），则bucket被再次创建并分区里面的东西都放在这个桶里了
等等。如果每个部分的格式相同，那么它们将进入与前一部分相同的存储桶。否则，将创建一个新的bucket

因此，对于每个文档，根据分离存储桶的逻辑，文档可能会以如下方式结束：

<body>
  <div class="FormatOne">
    <h1>Title 1</h1>
    <p>paragraph 1-1</p>
    <p>paragraph 1-2</p>
    <h3>Subtitle 2</h3>
    <ul>
      <li>list item 2-1</li>
      <li>list item 2-2</li>
      <li>list item 2-3</li>
      <li>list item 2-4</li>
    </ul>
  </div>
  <div class="FormatTwo">
    <span class="warningText">
      Warning: This product could kill you
    </span>
  </div>
  <div class="FormatOne">
    <span class="disclaimerText"> You were warned</span>
    <p class="copyright">Copyright 1999-2011</p>
  </div>
</body>

这个：

<body>
  <div class="FormatOne">
    <h1>Title 1</h1>
    <p>paragraph 1-1</p>
    <p>paragraph 1-2</p>
    <h3>Subtitle 2</h3>
  </div>
  <div class="FormatTwo">
    <ul>
      <li>list item 2-1</li>
      <li>list item 2-2</li>
      <li>list item 2-3</li>
      <li>list item 2-4</li>
    </ul>
  </div>
  <div class="FormatOne">
    <span class="warningText">
      Warning: This product could kill you
    </span>
    <span class="disclaimerText"> You were warned</span>
    <p class="copyright">Copyright 1999-2011</p>
  </div>
</body>

甚至这个：

<body>
  <div class="FormatOne">
    <h1>Title 1</h1>
    <p>paragraph 1-1</p>
    <p>paragraph 1-2</p>
    <h3>Subtitle 2</h3>
    <ul>
      <li>list item 2-1</li>
      <li>list item 2-2</li>
      <li>list item 2-3</li>
      <li>list item 2-4</li>
    </ul>
    <span class="warningText">
      Warning: This product could kill you
    </span>
    <span class="disclaimerText"> You were warned</span>
    <p class="copyright">Copyright 1999-2011</p>
  </div>
</body>

这取决于区段的定义方式。

有没有一种方法可以使用XSLT来执行这种类型的分组魔术？

任何帮助都会很棒。谢谢

我提出了一个解决方案，其中包括按顺序点击每个部分。每个部分的处理分为两部分："外壳"one_answers"内容"部分。"shell"负责渲染<div class="FormatOne">...</div>位，"contents"负责渲染当前节的实际内容和所有后续节，直到找到不匹配的节。

当找到不匹配的节时，控件将恢复到该节的"shell"模板。

这提供了一个有趣的灵活性："shell"模板在匹配内容方面可能非常激进，而"内容"部分可能更具辨识度。具体来说，对于第一个示例输出，您需要warning元素显示为<span class="warningText">...</span>，这是通过一个更匹配的模板来实现的。

所有"内容"模板在呈现其当前部分的内容后，都会调用一个命名模板来查找"下一个"适当的内容部分。这有助于整合确定哪些内容符合"匹配"部分的规则。

你可以在这里看到一个工作示例。

这是我的代码，它是为了复制您在第一个示例中所要求的内容而构建的：

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" />
    <xsl:template match="/">
        <body>
            <xsl:apply-templates select="/root/section[1]" mode="shell" />
        </body>
    </xsl:template>
    <xsl:template match="section[
        @attr = 'someCriteria' or
        @attr = 'someOtherCriteria' or
        @attr = 'evenMoreCriteria' or
        @attr = 'criteriaSupreme']" mode="shell">
        <div class="FormatOne">
            <xsl:apply-templates select="." mode="contents" />
        </div>
        <xsl:apply-templates select="following-sibling::section[
            @attr != 'someCritera' and
            @attr != 'someOtherCriteria' and
            @attr != 'evenMoreCriteria' and
            @attr != 'criteriaSupreme'][1]" mode="shell" />
    </xsl:template>
    <xsl:template name="nextFormatOne">
        <xsl:variable name="next" select="following-sibling::section[1]" />
        <xsl:if test="$next[
            @attr = 'someCriteria' or
            @attr = 'someOtherCriteria' or
            @attr = 'evenMoreCriteria' or
            @attr = 'criteriaSupreme']">
            <xsl:apply-templates select="$next" mode="contents" />
        </xsl:if>
    </xsl:template>
    <xsl:template match="section[
        @attr = 'someCriteria' or
        @attr = 'someOtherCriteria']" mode="contents">
        <xsl:copy-of select="*" />
        <xsl:call-template name="nextFormatOne" />
    </xsl:template>
    <xsl:template match="section[@attr = 'evenMoreCriteria']" mode="contents">
        <span class="disclaimerText">
            <xsl:value-of select="disclaimer" />
        </span>
        <xsl:call-template name="nextFormatOne" />
    </xsl:template>
    <xsl:template match="section[@attr = 'criteriaSupreme']" mode="contents">
        <p class="copyright">
            <xsl:value-of select="p" />
        </p>
        <xsl:call-template name="nextFormatOne" />
    </xsl:template>
    <xsl:template match="section[@attr = 'anotherSetOfCriteria']" mode="shell">
        <div class="FormatTwo">
            <xsl:apply-templates select="." mode="contents" />
        </div>
        <xsl:apply-templates select="
            following-sibling::section[@attr != 'anotherSetOfCriteria'][1]"
            mode="shell" />
    </xsl:template>
    <xsl:template name="nextFormatTwo">
        <xsl:variable name="next" select="following-sibling::section[1]" />
        <xsl:if test="$next[@attr = 'anotherSetOfCriteria']">
            <xsl:apply-templates select="$next" mode="contents" />
        </xsl:if>
    </xsl:template>
    <xsl:template
        match="section[@attr = 'anotherSetOfCriteria']"
        mode="contents">
        <span class="warningText">
            <xsl:value-of select="warning" />
        </span>
        <xsl:call-template name="nextFormatTwo" />
    </xsl:template>
</xsl:stylesheet>

"如果每个部分的格式相同，则它们将进入与前一部分相同的bucket。如果不是，则创建一个新bucket。"

您所描述的基本上是指令执行的任务

<xsl:for-each-group group-adjacent="....">

在XSLT2.0中。这假设您可以编写一个函数，将您的"criteria"转换为bucket名称，并在group neighbor属性中调用该函数。

那么，您需要使用XSLT1.0的约束有多困难呢？

如果您一直使用1.0，那么您将不得不使用Chris Nielsen提出的同级递归设计模式。

检查template、if、choose和for-each:

http://www.w3schools.com/xsl/xsl_templates.asp
http://www.w3schools.com/xsl/xsl_if.asp
http://www.w3schools.com/xsl/xsl_choose.asp
http://www.w3schools.com/xsl/xsl_for_each.asp

这些（以及其他XSLT元素）将允许您进行条件行为，以便在不同的转换逻辑之间切换。

相关内容

最新更新

热门标签：