删除awk文件中的前导零

Question

我正在使用awk文件生成一个报告，以提取数据并写入另一个文件。文件名：dosreport.awk。此代码打印的物料编号如下000000000000787301

if (substr($0, 1, 7) == "E2EDP19" && E2EDP19seen == 1)
                {
                    printf " " substr($2, 6);
                    E2EDP19seen=E2EDP19seen +1;
                }

相关数据为E2EDP19001 02002000000000000797578我需要去掉前导零，只给我787301。同样，这是在awk文件中，所以管道到awk命令将不起作用。

对原始printf进行打字将得到预期值。工作代码

if (substr($0, 1, 7) == "E2EDP19" && E2EDP19seen == 1)
                {
                    if (substr($2, 6)+0 == 0)
                    {
                        printf " " substr($2, 6);
                    }
                    else{
                        printf " " substr($2, 6)+0;
                    }
                    E2EDP19seen=E2EDP19seen +1;
                }

Answer 1

试试这个：sub(/^0+/, "", $2)？

$ awk 'BEGIN{b="000000000000787301"; sub(/^0+/, "", b); print b;}'
787301

或者通过加零进行打字：

$ awk 'BEGIN{b="000000000000787301"; print b+0;}'
787301

更新基于注释的工作示例：

$ echo 'E2EDP19001 02002000000000000797578' | awk '{$2 = substr($2,6); sub(/^0+/, "", $2); print $2;}'
797578

或者，保留$2:

$ echo 'E2EDP19001 02002000000000000797578' | awk '{a = substr($2,6); sub(/^0+/, "", a); print a;}'
797578

更新基于修订后的帖子，这里有一个工作样本，就像我之前提出的很多修订一样：

sub()

$ echo 'E2EDP19001                                                   02002000000000000797578' 
   | awk 'BEGIN {E2EDP19seen = 1 } 
       {if (substr($0, 1, 7) == "E2EDP19" && E2EDP19seen == 1) {
       out = substr($2, 6); sub(/^0+/, "", out); print out } }'
797578

打字

$ echo 'E2EDP19001                                                   02002000000000000797578' 
  | awk 'BEGIN {E2EDP19seen = 1 } 
      {if (substr($0, 1, 7) == "E2EDP19" && E2EDP19seen == 1) {
      print substr($2, 6) + 0 } }'
797578