根据Windows版本在Inno Setup Run部分中执行不同的命令块

Question

我知道已经有问题在基于Windows版本的Inno Setup Run部分中执行不同的命令，答案非常好。

我的问题是如何为不同的目标Windows版本执行不同的命令块。我的问题是，如果目标版本是 Windows 7，并且 Windows 8 或更高版本需要执行 ~10-15 个命令，则需要执行 ~8 个命令。

是否可以避免在第一种情况下所需的每个命令之后添加; OnlyBelowVersion: 6.2，并在第二个块中的每个命令之后添加; MinVersion: 6.2？

我知道有预处理器条件"#if"、#else和#endif，但这当然只在编译时有效

问题和答案在Inno安装程序中确定Windows版本，尽管可能看起来与此问题相似，但没有回答它。我知道如何在Inno Setup中确定Windows版本。我也知道这些; MinVersion: 6.2和; OnlyBelowVersion: 6.2选择。我问是否可以指定一个命令块（10-15 个命令）并将该选项应用于整个块，而不是单独应用于每个命令。

目标不是避免"神秘的版本号"，而是避免多次重复相同的条件。并避免在块会随着时间的推移而增长时忘记它的风险。

到目前为止，我找到的解决方案是使用以下过程CurStepChanged：

procedure CurStepChanged(CurStep: TSetupStep);
begin
   if CurStep = ssPostInstall then
      if IsWindows8OrLater() then
         MsgBox('Running on Windows 8 Or Later', mbInformation, MB_OK)
         { 15 comands or call of W8-specific procedure goes here }
      else begin
         MsgBox('Running on Windows 7', mbInformation, MB_OK);
         { 15 comands or call of W7-specific procedure goes here }
      end;
end;

但对我来说看起来有点丑...

Answer 1

.iss文件中没有块控制功能。

为了避免重复神秘的版本号，您所能做的就是定义一个预处理器变量，如下所示：

#define Windows8AndNewer "MinVersion: 6.2"
#define Windows7AndOlder "OnlyBelowVersion: 6.2"
[Run]
Filename: "Windows8-Command1.exe"; {#Windows8AndNewer}
Filename: "Windows8-Command2.exe"; {#Windows8AndNewer}
Filename: "Windows7-Command1.exe"; {#Windows7AndOlder}
Filename: "Windows7-Command2.exe"; {#Windows7AndOlder}

---

唯一的其他方法是使用 Exec 函数重新实现[Code]中的[Run]部分：

procedure Run(FileName: string);
var
  ResultCode: Integer;
begin
  Exec(FileName, '', '', SW_SHOW, ewWaitUntilTerminated, ResultCode);
  { some error checking }
end;
procedure CurStepChanged(CurStep: TSetupStep);
begin
  if CurStep = ssPostInstall then
  begin
    if GetWindowsVersion() >= $06020000 then
    begin
      Log('Running on Windows 8 or later');
      Run('Windows8-Command1.exe');
      Run('Windows8-Command2.exe');
    end
      else
    begin
      Log('Running on Windows 7 or older');
      Run('Windows7-Command1.exe');
      Run('Windows7-Command2.exe');
    end;
  end;
end;