PL/SQL对象组合:对象实例化/构造函数的问题

Question

这是PL/SQL中是否可以使用对象组合的后续问题?

这个问题讨论了如何在PL/SQL中创建相互依赖的对象类型(即每个对象的一个属性是对另一个对象的引用)。

我遇到的下一个问题与对象构造函数有关。下面是代码(逻辑上，student存在于person中)。另外，为了在注释中排除这种情况，使用继承对我来说不是一个选项。

Person对象

CREATE OR REPLACE TYPE PERSON FORCE AUTHID DEFINER UNDER MYSCHEMA.BASE_OBJECT (
    student MYSCHEMA.student,
    additional attributes...
    CONSTRUCTOR FUNCTION PERSON
    RETURN SELF AS RESULT
) NOT FINAL; 
CREATE OR REPLACE TYPE BODY PERSON
AS
    CONSTRUCTOR FUNCTION PERSON
    RETURN SELF AS RESULT IS
    BEGIN
        self.student := NEW MYSCHEMA.STUDENT(self);
        RETURN;
    END;
END;

学生对象

CREATE OR REPLACE TYPE STUDENT FORCE AUTHID DEFINER UNDER MYSCHEMA.BASE_OBJECT (
    person REF MYSCHEMA.PERSON,
    CONSTRUCTOR FUNCTION STUDENT(p_person REF MYSCHEMA.PERSON)
    RETURN SELF AS RESULT
) NOT FINAL; 
CREATE OR REPLACE TYPE BODY STUDENT
AS
    CONSTRUCTOR FUNCTION STUDENT(p_person REF MYSCHEMA.PERSON)
    RETURN SELF AS RESULT IS
    BEGIN
        self.person := p_person;
        RETURN;
    END;
END;

这段代码将编译没有任何错误，除了PERSON构造函数中的下面一行，它在PERSON内部实例化了一个STUDENT对象:

self.student := NEW MYSCHEMA.STUDENT(self);

抛出以下错误:

Error(22,29): PLS-00306: wrong number or types of arguments in call to 'STUDENT'

所以，亲爱的朋友们，我再次寻求你们的帮助。我猜有一个额外的参数被隐式地传递给STUDENT构造函数，但这只是一个猜测。

谢谢。

Answer 1

REF必须引用一行。你不能传递SELF，因为它不是一个引用。

一种方法是创建一个隐藏表:

create table shadow_person of person;

并且每个实例都秘密地在该表中创建一行:

CONSTRUCTOR FUNCTION PERSON
RETURN SELF AS RESULT IS
    v_ref_person ref person;
BEGIN
    insert into shadow_person values(self)
    returning make_ref(shadow_person, object_id) into v_ref_person;
    self.a_student := new student(v_ref_person);
    RETURN;
END;

这似乎是有效的，但可能有非常可怕的副作用，没有人希望在实际的生产环境中。

下面是完整的脚本:

drop type base_object force;
drop type student force;
drop type person force;
drop table shadow_person;

create or replace type base_object is object (a varchar2(10)) not final;
/
CREATE OR REPLACE TYPE PERSON FORCE AUTHID DEFINER UNDER BASE_OBJECT (
    b varchar2(10),
    CONSTRUCTOR FUNCTION PERSON RETURN SELF AS RESULT
) NOT FINAL; 
/
CREATE OR REPLACE TYPE STUDENT FORCE AUTHID DEFINER UNDER BASE_OBJECT (
    c varchar2(10),
    a_person REF PERSON,
    CONSTRUCTOR FUNCTION STUDENT(p_person ref PERSON) RETURN SELF AS RESULT
) NOT FINAL; 
/
alter type person add attribute a_student student cascade;
create table shadow_person of person;
CREATE OR REPLACE TYPE BODY PERSON
AS
    CONSTRUCTOR FUNCTION PERSON
    RETURN SELF AS RESULT IS
        v_ref_person ref person;
    BEGIN
        insert into shadow_person values(self)
        returning make_ref(shadow_person, object_id) into v_ref_person;
        self.a_student := new student(v_ref_person);
        RETURN;
    END;
END;
/
CREATE OR REPLACE TYPE BODY STUDENT
AS
    CONSTRUCTOR FUNCTION STUDENT(p_person REF PERSON)
    RETURN SELF AS RESULT IS
    BEGIN
        self.a_person := p_person;
        RETURN;
    END;
END;
/

--Example of how to use it:
declare
    v_person person := person;
begin
    v_person.a := 'person a';
    v_person.b := 'b';
    v_person.a_student.a := 'student a';
    v_person.a_student.c := 'c';
    dbms_output.put_line(v_person.a_student.c);
end;
/

Answer 2

Ok!既然我自己也在处理这个问题，我想分享一下我们是如何解决的!!

首先，在Oracle中没有直接的方法来解决内存循环依赖- ，但是我们可以作弊:-)

只是为了注释- REF只与存储对象一起工作，并且不容易被PL/SQL访问，所以在大多数情况下不是一个选项!

但是你可以通过使用继承和强制转换来解决这个问题!

只需定义一个几乎没有属性的基类型，并在该基类型下创建类型。现在，所有类型都可以具有基类型的属性，因为基类型没有对任何其他类型的引用—所以它不是循环的:-)

访问子类型的属性时，只需将它们转换为适当的类型即可访问它们的属性和方法!

在您的示例中，只需定义BASE_OBJECT类型的所有属性，就可以开始了!

*我有点自豪我已经弄清楚了，因为我没有找到任何关于这个的东西!!

CREATE OR REPLACE TYPE test_base FORCE IS OBJECT(id NUMBER) NOT FINAL;
/
CREATE OR REPLACE TYPE test_person FORCE UNDER test_base
  ( student test_base
   ,name        varchar2(100)
  );
/
CREATE OR REPLACE TYPE test_student FORCE UNDER test_base
  ( person test_base
   ,university  VARCHAR2(100)
  );
/
DECLARE
  pers test_person;
  stud test_student;
BEGIN
  pers := test_person(1, NULL, 'Mike Ross');
  stud := test_student(2, pers, 'Havard');
  pers.student := stud;
  DBMS_OUTPUT.PUT_LINE('Name: '||pers.NAME);
  DBMS_OUTPUT.PUT_LINE('University:'||TREAT(stud AS test_student).university);
END;
/