将莱宁根repl的结果复制到剪贴板中

Question

偶尔我想在其他软件的repl中戳一个结果。有没有一种方便的方法可以将repl中运行的函数的结果复制到系统剪贴板？我知道我可以把结果spit输出到一个文件中。我使用的是macosx.

Answer 1

您可以始终重新绑定*out*特殊变量，以指向新位置。例如，您可以将所有输出收集到字符串：

user> (def result (java.io.StringWriter.))
#'user/result
user> (binding [*out* result]
        (println :aaa)
        (println :bbb))
nil
user> (str result)
":aaan:bbbn"

这是一个临时绑定，表明*out*在binding块之外是完整的：

user> (println :aaa)
:aaa
nil

还可以使用set!:在线程级别上重置out

user> (def result (java.io.StringWriter.))
#'user/result
user> (set! *out* result)
#object[java.io.StringWriter 0x66c129d9 ""]
user> (println :aaa)
nil
user> (println :bbb)
nil
user> (str result)
":aaan:bbbn"

然后，您可以使用java.awt类将此字符串放入剪贴板：

user> (import 'java.awt.Toolkit)
java.awt.Toolkit
user> (import 'java.awt.datatransfer.StringSelection)
java.awt.datatransfer.StringSelection
user> (.. Toolkit
          (getDefaultToolkit)
          (getSystemClipboard)
          (setContents (StringSelection. (str result)) nil))
nil

就是这样。现在就把它贴起来。在mac上应该可以正常工作。

然后你可以用一个宏来概括它：

(defmacro with-clipboard [& body]
  `(binding [*out* (java.io.StringWriter.)]
     (let [result# (do ~@body)]
       (.. Toolkit
           (getDefaultToolkit)
           (getSystemClipboard)
           (setContents (StringSelection. (str *out*)) nil))
       result#)))

并像这样使用：

user> (with-clipboard
        (println :hello)
        (println :clipboard)
        (+ 10 20))
;; => 30

剪贴板将包含：

:hello
:clipboard