交替使用两个值

Question

我有代码

(define alternate
(letrec ([f (lambda (x) (cons x (lambda () (f (+ x 1)))))])
(lambda () (f 1))))

结果是1,2,3。。我怎么能把它改成1，2，1，2…

我在f里面试了试，但没有成功。有什么想法吗？

Answer 1

您可能还发现生成器很有用：docs

Welcome to DrRacket, version 5.3.3.5 [3m].
Language: racket [custom].
> (require racket/generator)
> (define g (generator () (let LOOP () (yield 1) (yield 2) (LOOP))))
> (g)
1
> (g)
2
> (g)
1
> (g)
2

更新：

更好的是，使用无限生成器：

Welcome to DrRacket, version 5.3.3.5 [3m].
Language: racket [custom].
> (require racket/generator)
> (define g (infinite-generator (yield 1) (yield 2)))
> (g)
1
> (g)
2
> (g)
1
> (g)
2

Answer 2

使用流很容易实现：

(define (alternate)
  (stream-map (lambda (x)
                (if (even? x) 1 2))
              (in-naturals)))

这里的诀窍是，流是使用流cons构建的，它基本上完成了您手动实现的事情：它创建了一个列表，其中的元素是"承诺"，只有在需要时才会进行评估。

stream-cons产生惰性流，其中流首先强制对第一expr进行求值以产生流的第一元素，流rest强制对rest expr进行赋值以产生返回流的其余部分的流。

这显示了alternate如何返回形式为1 2 1 2 1 2 ... 的元素的无限流

(define alt (alternate))
(stream-ref alt 0)
=> 1
(stream-ref alt 1)
=> 2
(stream-ref alt 2)
=> 1
(stream-ref alt 3)
=> 2

或者，如果您需要序列中n元素的列表，请使用此程序，顺便说一句，它应该首先是Racket的一部分：

(define (stream-take s n)
  (if (zero? n)
      '()
      (cons (stream-first s)
            (stream-take (stream-rest s) (sub1 n)))))

现在它按预期工作：

(define alt (alternate))
(stream-take alt 0)
=> '()
(stream-take alt 1)
=> '(1)
(stream-take alt 2)
=> '(1 2)
(stream-take alt 3)
=> '(1 2 1)

Answer 3

以下是对现有代码进行小修改的方法：

(define alternate
  (letrec ([f (lambda (x) (cons x (lambda () (f (if (= x 1) 2 1)))))])
    (lambda () (f 1))))