Emacs中是否包含递归遍历目录结构并调用函数的函数?

Question

我想从一个特定的点递归地沿着目录结构向下走，并在每一层调用copyright-update-directory。

是否有一个功能包含在Emacs 24，将有助于这一点?例如:

(recursive-directory-walk "~/src/foo" '(copyright-update-directory))

如果没有这样的函数存在，一些关于如何开始实现它(或工作实现)的指针将是伟大的。

Answer 1

MELPA上的f.el库(github)包含遍历文件系统的函数。

(mapc 'copyright-update-directory (f-directories "~/path" nil t))

这将递归地降低目录层次结构。

Answer 2

不确定是否存在，但编写自己的代码并不难。

(defun folder-dirs (folder)
  (delete-if-not 'file-directory-p
    (mapcar (lambda(arg) (file-name-as-directory (concat (file-name-as-directory folder) arg)))
      (delete-if (lambda (arg) (or (string= ".." arg) (string= "." arg)))
        (directory-files folder)))))
(defun recursively-run-on-every-dir (fn folder)
"FN - function, taking one argument; 
FOLDER - initial forder"
  (funcall fn folder)
  (mapc (lambda(arg) (recursively-run-on-every-dir fn arg))
    (folder-dirs folder))
  nil)
;; use your function instead of print
(recursively-run-on-every-dir 'print "/your/initial/path/")

Answer 3

Emacs具有用于此目的的递归内置函数directory-files:

(mapc #'YOUR-FUNCTION
      (remove-if-not
       #'file-directory-p       ;only dirs
       (directory-files-recursively YOUR-DIRECTORY "" t)))

它也比另一个答案中提到的f-directories函数快得多，因为它不使用内部递归

Answer 4

就用find-lisp

(require 'find-lisp)
;;  a simple function, just to test
(defun my-funct (x)
  (princ x)
  (terpri))
(mapc 'my-funct (find-lisp-find-files "~/src/foo/" "\.txt$"))

Answer 5

我认为Chris Barrett的回答是正确的和惯用的。然而，出于学习的目的，我想实现Python的os.walk，这是一个用于目录树的宽度优先遍历的通用函数。我使用dash.el列表库和f.el文件和目录库。这是从Python翻译过来的基于堆栈的实现。

(defun walk (path)
  (let ((stack (list (f-full path)))
        result)
    (while stack
      (let* ((path (pop stack))
             (ds_ (f-directories path))
             (ds (-map 'f-relative ds_))
             (fs (-map 'f-relative (f-files path))))
        (--each ds_ (!cons it stack))
        (!cons (list path ds fs) result)))
    (reverse result)))

参见函数:f-full, pop, f-directories, f-relative, f-files, --each, !cons, reverse。现在你可以在循环中使用它，就像在Python中使用它一样:

(loop for (b ds fs) in (walk path)
      do (copyright-update-directory b "*"))