在 VBS 中，EPOC 日期到正常系统日期

Question

我读过很多帖子，但没有什么真正有帮助的。我的问题看起来很相似，但有点不同。

我必须将 EPOC 时间更改为系统时间格式。

data type = datetime
value= 20160630165419.634204+060

期望的输出数据类型 = 日期时间

value= 30/06/2016 16:54:19

由于EPOC值在点后有数字，数据类型是日期时间，这使得很难在循环中将其除以10并获得整数值。请仅针对给定的输入格式提出解决方案。

Answer 1

您可以使用

此函数WMIDateStringToDate转换您的日期：

WScript.echo WMIDateStringToDate("20160227235343.000000+060")
WScript.echo WMIDateStringToDate("20160630165419.634204+060")
'************************************************************
Function WMIDateStringToDate(Mydate)
 WMIDateStringToDate = CDate(Mid(Mydate, 5, 2) & "/" & _
 Mid(Mydate, 7, 2) & "/" & Left(Mydate, 4) _
 & " " & Mid (Mydate, 9, 2) & ":" & _
 Mid(Mydate, 11, 2) & ":" & Mid(Mydate,13, 2))
End Function
'************************************************************

Answer 2

第 1 步：对从输入 （Mid（）） 中提取的数字 （CInt（）） 使用 DateSerial（） 和 TimeSerial（） 来获取子类型 Date 的变体

第 2 步：使用 SetLocale（） 和 Replace（） 格式化/字符串化日期

>> SetLocale "de-de"
>> sX = "20160630165419.634204+060"
>> dtD = DateSerial(CInt(Mid(sX, 1, 4)), CInt(Mid(sX, 5, 2)), CInt(Mid(sX, 7, 2)))
>> dtT = TimeSerial(CInt(Mid(sX, 9, 2)), CInt(Mid(sX, 11, 2)), CInt(Mid(sX, 13,2)))
>> dtX = dtD + dtT
>> WScript.Echo dtX, TypeName(dtX)
>> WScript.Echo Replace(dtX, ".", "/")
>>
30.06.2016 16:54:19 Date
30/06/2016 16:54:19

危险，威尔·鲁滨逊！看看这个测试脚本：

Function WMIDateStringToDate(Mydate)
 WMIDateStringToDate = CDate(Mid(Mydate, 5, 2) & "/" & _
 Mid(Mydate, 7, 2) & "/" & Left(Mydate, 4) _
 & " " & Mid (Mydate, 9, 2) & ":" & _
 Mid(Mydate, 11, 2) & ":" & Mid(Mydate,13, 2))
End Function
'************************************************************
For Each sLocale In Split("de-de en-us")
    SetLocale sLocale
    For Each sDate In Split("20160227235343.000000+060 20160203235343.000000+060")
      On Error Resume Next
       dtX = WMIDateStringToDate(sDate)
       If Err.Number Then dtX = Err.Description
      On Error GoTo 0
       WScript.Echo GetLocale(), sD, sDate, dtX
    Next
Next

及其输出：

cscript 38249865.vbs
1031  20160227235343.000000+060 27.02.2016 23:53:43
1031  20160203235343.000000+060 02.03.2016 23:53:43
1033  20160227235343.000000+060 27.02.2016 23:53:43
1033  20160203235343.000000+060 03.02.2016 23:53:43

查看原因：

任何Microsoft标准都不支持示例脚本 支持计划或服务。示例脚本按原样提供 不提供任何形式的保证。Microsoft进一步否认所有暗示 保证包括但不限于任何默示保证 适销性或特定用途的适用性。整个 因使用或执行示例脚本而产生的风险，以及 文档仍由您保留。在任何情况下都不得Microsoft，其 作者，或参与创作、制作的任何其他人，或 交付脚本对任何损害负责 （包括但不限于商业利润损失的损害赔偿， 业务中断、业务信息丢失或其他 因使用或无法使用 示例脚本或文档，即使已告知Microsoft 此类损害的可能性。 （在这里找到）