是否可以在没有.DFM的情况下使用数据模块

Question

我在一个单独的数据模块中卸载了所有ADO引擎盖，因此一个模块可以被多个应用程序引用。我的所有应用程序基本上只需要两种worker方法来访问数据：

CCD_ 1以CCD_
AdoExecute执行简单的更新/删除查询而不获取任何结果。

这是类结构：

type
  TMyDataModule = class(TDataModule)
    procedure DataModuleCreate(Sender: TObject);
    procedure DataModuleDestroy(Sender: TObject);
  private
    procedure pvtAdoConnect;
    procedure pvtAdoExecute(const sql: string);
    function pvtAdoQuery(const sql: string): TADODataSet;
  public
    AdoConnection: TADOConnection;
  end;

然后，我向类方法添加了两个公开的包装器。我用它来避免调用中的长类引用：

function AdoQuery(const sql: string): TADODataSet;
procedure AdoExecute(const sql: string);
implementation
function AdoQuery(const sql: string): TADODataSet;
begin
  Result := MyDataModule.pvtAdoQuery(sql);
end;

上面是我从所有表单中调用的worker函数。

AdoConnect仅在DataModuleCreate事件上运行一次。TDatModule派生自TPersistent，它允许在整个运行时中持久化单个连接实例。

到目前为止，唯一让我恼火的是一个无用的DFM，我根本不需要它
有什么办法可以摆脱它吗？

Answer 1

我会用两种方式之一处理这种类型的事情，一种是接口，另一种是继承。在这种情况下，我不愿意将类暴露在外部世界。第二个几乎可以称为没有接口的接口：）

接口

此版本返回一个包含所需方法的接口。外部世界只需要使用接口。我们对实施细节保密。我们的TMyDBClass实现了我们向外部世界公开的接口，并且我们的全局函数GetDBInterface返回单个实例。

interface
uses
  ADODB;
type
  IMyDBInterface = interface
  ['{2D61FC80-B89E-4265-BB3D-93356BD613FA}']
    function AdoQuery(const sql: string): TADODataSet;
    procedure AdoExecute(const sql: string);
  end;
function GetDBInterface: IMyDBInterface;
implementation
type
  TMyDBClass = class(TInterfacedObject, IMyDBInterface)
  strict private
    FConnection: TADOConnection;
  protected
    procedure AfterConstruction; override;
    procedure BeforeDestruction; override;
  public
    function AdoQuery(const sql: string): TADODataSet;
    procedure AdoExecute(const sql: string);
  end;
var
  FMyDBInterface: IMyDBInterface;
procedure TMyDBClass.AdoExecute(const sql: string);
begin
  // ...
end;
function TMyDBClass.AdoQuery(const sql: string): TADODataSet;
begin
  // ...
end;
procedure TMyDBClass.AfterConstruction;
begin
  inherited;
  FConnection := TADOConnection.Create(nil);
end;
procedure TMyDBClass.BeforeDestruction;
begin
  FConnection.Free;
  inherited;
end;
// Our global function
function GetDBInterface: IMyDBInterface;
begin
  if not Assigned(FMyDBInterface) then
    FMyDBInterface := TMyDBClass.Create;
  Result := FMyDBInterface;
end;
initialization
finalization
  FMyDBInterface := nil;
end.

继承

此版本使用具有所需方法的基类。这对人们来说更容易处理，因为它排除了对刚开始的人来说可能很复杂的界面。同样，我们向用户隐藏了实现细节，只公开了一个类的外壳，其中包括我们希望人们访问的两个方法。这些方法的实现由实现中从公开类继承的类执行。我们还有一个全局函数，它返回这个类的实例。与此方法相比，接口方法的最大优点是该对象的用户不能意外释放该对象。

interface
uses
  ADODB;
type
  TMyDBClass = class(TObject)
  public
    function AdoQuery(const sql: string): TADODataSet; virtual; abstract;
    procedure AdoExecute(const sql: string); virtual; abstract;
  end;
function GetDBClass: TMyDBClass;
implementation
type
  TMyDBClassImplementation = class(TMyDBClass)
  strict private
    FConnection: TADOConnection;
  protected
    procedure AfterConstruction; override;
    procedure BeforeDestruction; override;
  public
    function AdoQuery(const sql: string): TADODataSet; override;
    procedure AdoExecute(const sql: string); override;
  end;
var
  FMyDBClass: TMyDBClassImplementation;
procedure TMyDBClassImplementation.AdoExecute(const sql: string);
begin
  inherited;
  // ...
end;
function TMyDBClassImplementation.AdoQuery(const sql: string): TADODataSet;
begin
  inherited;
  // ...
end;
procedure TMyDBClassImplementation.AfterConstruction;
begin
  inherited;
  FConnection := TADOConnection.Create(nil);
end;
procedure TMyDBClassImplementation.BeforeDestruction;
begin
  FConnection.Free;
  inherited;
end;
// Our global function
function GetDBClass: TMyDBClass;
begin
  if not Assigned(FMyDBClass) then
    FMyDBClass := TMyDBClassImplementation.Create;
  Result := FMyDBClass;
end;
initialization
  FMyDBClass := nil;
finalization
  FMyDBClass.Free;
end.

用法

使用这些真的很容易。

implementation
uses
  MyDBAccess; // The name of the unit including the code
procedure TMyMainForm.DoSomething;
var
  myDataSet: TADODataSet;
begin
  myDataSet := GetDBInterface.AdoQuery('SELECT * FROM MyTable');
  ...
  // Or, for the class version
  myDataSet := GetDBClass.AdoQuery('SELECT * FROM MyTable');
  ...
end;

Answer 2

如果您的数据模块中没有任何设计时的非可视化组件，也不打算这样做，那么您根本不需要数据模块。整个目的是用于设计时组件和其他实现，如Web模块甚至Windows服务应用程序。但不适用于包装没有设计时组件的纯代码。

此外，正如评论中提到的，不要混淆TPersistent的含义。这个类的使用方式完全不同，可以集成到IDE对象检查器中（作为组件中的子属性）。

因此，理想的做法是将所有内容封装在一个类中。为了您的目的，数据库连接。。。

type
  TMyData = class(TObject)
  private
    FConnection: TADOConnection;
  public
    constructor Create;
    destructor Destroy; override;
    procedure pvtAdoConnect;
    procedure pvtAdoExecute(const sql: string);
    function pvtAdoQuery(const sql: string): TADODataSet;
    ...
  end;
implementation
{ TMyData }
constructor TMyData.Create;
begin
  FConnection:= TADOConnection.Create(nil);
end;
destructor TMyData.Destroy;
begin
  FConnection.Connected:= False;
  FConnection.Free;
  inherited;
end;

至于"持久性"的解释，您可以通过多种方式创建/销毁它的实例。例如，您可以使用单元的initialization和AdoQuery0部分（需要CoInitialize），也可以让主窗体在创建时初始化全局实例。

一种常见的方法是添加。。。

interface
function MyData: TMyData;
implementation
var
  _MyData: TMyData;
function MyData: TMyData;
begin
  if not Assigned(_MyData) then
    _MyData:= TMyData.Create;
  Result:= _MyData;
end;
initialization
  _MyData:= nil;
finalization
  _MyData.Free;
end.

第一次从任何地方调用MyData时，都会实例化一个新的全局实例。然后，它每重复使用一次相同的实例。这也解决了ActiveX和CoInitialize等的需要，因为在这一点上，COM预计已经被实例化（这是ADO所必需的）。

该单元的使用将非常简单——使用将其包含在uses中的任何位置，并通过MyData函数访问其实例。

票据

你应该改掉全局变量的习惯。这是在为以后的工作找麻烦。上面的示例显示了如何适应全局对象实例。所有其他变量在该对象中都应该是自包含的，或者通常是范围/相关性的一个。TADOConnection的整个控制应该在这里，包括连接/断开连接、异常处理、分配连接字符串。

Answer 3

如果您可能对没有DataModules的替代方案感兴趣，请查看以下内容：https://github.com/stijnsanders/xxm/blob/master/Delphi/demo2/03%20Data%20ADO/xxmData.pas

查询存储在一个.sql文件中，在特定的SQL编辑器或工作台中进行编辑非常方便。查询用一行--"QueryName"分隔，并在启动时加载到查询存储中。假设您大部分时间都在查询较小的记录集，那么最好的锁定和打开样式是只读和静态的，这将提供尽可能好的性能和最小的数据库服务器负载。获取字段值使用TADODataSet0调用，这也提供了一点性能增益。