使用XSLT将路径列表转换为树结构

Question

我有一个路径列表，我需要把它做成树状结构。此外，我需要添加一些与每个级别相关的特定信息。

示例输入

<root>
  <data>2013</data>
  <data>2013/1</data>
  <data>2013/1/0</data>
  <data>2013/1/1</data>
  <data>2013/1/2</data>
  <data>2013/2</data>
  <data>2013/2/0</data>
  <data>2013/2/1</data>
  <data>2013/2/2</data>
  <data>2013/2/3</data>
</root>

我需要让它看起来像这样例如:

<root>
  <year value="2013">
    <info />
    <month value="1">
      <info />
      <day value="0">
        <info />
      </day>
      <day value="1">
        <info />
      </day>
      ...
    </month>
    ...
  </year>
  ...
</root>

其中info元素是我从其他地方获得的关于每个路径的信息。

我想我可能需要分组或其他什么，但从来没有使用过它，通常只是停留在这里。不知道该怎么对付。

Answer 1

使用XSL键可以相对容易地做到这一点。(这个答案是基于michael.hor257k)。

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output indent="yes"/>
  <xsl:key name="kLevel" match="data" use="
    string-length(.) - string-length(translate(., '/', ''))
  " />
  <xsl:template match="/*">
    <xsl:copy>
      <xsl:apply-templates mode="year" select="key('kLevel', 0)" />
    </xsl:copy>
  </xsl:template>
  <xsl:template match="data" mode="year">
    <year value="{.}">
      <xsl:apply-templates mode="month" select="key('kLevel', 1)[starts-with(., concat(current(), '/'))]" />
    </year>
  </xsl:template>
  <xsl:template match="data" mode="month">
    <month value="{substring-after(., '/')}">
      <xsl:apply-templates mode="day" select="key('kLevel', 2)[starts-with(., concat(current(), '/'))]" />
    </month>
  </xsl:template>
  <xsl:template match="data" mode="day">
    <day value="{substring-after(substring-after(., '/'), '/')}">
      <info />
    </day>
  </xsl:template>
</xsl:stylesheet>

,

<root>
  <year value="2013">
    <month value="1">
      <day value="0">
        <info />
      </day>
      <day value="1">
        <info />
      </day>
      <day value="2">
        <info />
      </day>
    </month>
    <month value="2">
      <day value="0">
        <info />
      </day>
      <day value="1">
        <info />
      </day>
      <day value="2">
        <info />
      </day>
      <day value="3">
        <info />
      </day>
    </month>
  </year>
</root>

Answer 2

我假设层次结构正好是给定的三层深度。如果每个关卡都需要一个具有自己名称的元素，那么就很难做到这一点。出于这个原因，每个关卡都有一个单独的模板是必要的，即使代码在很大程度上是相似的。否则，我们将需要某种查找目录来查找"month"后面的内容，例如

(编辑)
还假设每个数据元素(除了年份)都有一个"父"数据元素;也就是说，在转换过程中不需要创建中间元素。

XSLT 1.0

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:template match="/root">
    <xsl:copy>
        <xsl:apply-templates 
            select="data[not(contains(., '/'))]" 
            mode="year"/>
    </xsl:copy>
</xsl:template>
<xsl:template match="data" mode="year">
    <year value="{.}">
    <xsl:variable name="dir" select="concat(., '/')" />
        <xsl:apply-templates 
            select="/root/data
                [starts-with(., $dir)]
                [not (contains(substring-after(., $dir), '/'))]"
            mode="month"/>
    </year>
</xsl:template>
<xsl:template match="data" mode="month">
    <month value="{substring-after(., '/')}">
    <xsl:variable name="dir" select="concat(., '/')" />
        <xsl:apply-templates 
            select="/root/data
                [starts-with(., $dir)]
                [not (contains(substring-after(., $dir), '/'))]"
            mode="day"/>
    </month>
</xsl:template>
<xsl:template match="data" mode="day">
    <day value="{substring-after(substring-after(., '/'), '/')}">
    </day>
</xsl:template>
</xsl:stylesheet> 

当应用到你的输入时，结果是:

<?xml version="1.0" encoding="UTF-8"?>
<root>
   <year value="2013">
      <month value="1">
         <day value="0"/>
         <day value="1"/>
         <day value="2"/>
      </month>
      <month value="2">
         <day value="0"/>
         <day value="1"/>
         <day value="2"/>
         <day value="3"/>
      </month>
   </year>
</root>

---

info元素将是我从中获得的关于每个路径的信息别的地方。

我省略了这部分，因为我根本不清楚这将如何工作。

Answer 3

下面是使用XSLT2.0的样式表:

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" indent="yes"/>
<xsl:strip-space elements="*"/>
<xsl:template match="/">
    <root>
        <xsl:for-each-group select="root/data" group-by="tokenize(.,'/')[1]">
            <year value="{current-grouping-key()}">
                <info/>
                <xsl:for-each-group select="current-group()" group-by="tokenize(.,'/')[2]">
                    <month value="{current-grouping-key()}">
                        <info/>
                        <xsl:for-each-group select="current-group()" group-by="tokenize(.,'/')[3]">
                            <day value="{current-grouping-key()}">
                                <info/>
                            </day>
                        </xsl:for-each-group>
                    </month>
                </xsl:for-each-group>
            </year>
        </xsl:for-each-group>
    </root>
</xsl:template>
</xsl:stylesheet>