我导入了一个数据文件。它有246个观测值。通过使用nobs，我如何在代码的最后一句话中替换246来查找百分比?
proc import datafile='G:Data fileDec 2014.csv'
out=out.datafile
dbms=csv
replace;
*SUMMARY TABLE IS MADE;
proc summary data = out.datafile missing;
class AGE sentiment; *age, sentiment are two columns in datafile;
var ;
output out = out.summ_age ;
run;
*SORTING SUMMARY TABLE BY AGE;
proc sort data = out.summ_age;
by age;
run;
*TRANSPOSING THE SORTED DATA WITH AGE AS OBS SENTIMENT VALUES AS COLUMNS;
PROC transpose data = out.summ_age out = out.hsi_age;
by age;
id sentiment;
var count;
run;
data out.hsi_age;
set out.hsi_age;
tot = d+s+i;
PERCENTAGE=round((tot/246)*100,0.01); /*PERCENTAGE PER GROUP*/
run;
如果您想将数据集中的观测值数量放入宏变量中，那么您可以将此计数放入宏变量中-就像您的情况一样:
proc sql ;
select count(*)
into :N
from out.datafile ;
quit ;
你可以在最后一步调用它:
data out.hsi_age;
set out.hsi_age;
tot = d+s+i;
PERCENTAGE=round((tot/&N.)*100,0.01); /*PERCENTAGE PER GROUP*/
run;
所以，你有丢失和200%的原因，所有这些都是你的PROC SUMMARY生成的数据比你想要的多。你想要年龄和情感的交汇，但你却得到了:
- 年龄
- <
- 情绪/gh><
- 年龄*情绪/gh>
- 所有数据(合计)
你需要问你真正想要什么。这确实给了我们一个小小的奖励:你不必去寻找NOBS，你实际上可以从这些额外的一行(年龄不与情绪交叉)中得到它。
假设你有sashelp.class，用性代替情感，你可以这样做:
proc summary data = sashelp.class missing;
class AGE sex; *sex replaces sentiment here;
types sex age*sex; *we want the grand total for each separate sex, and crossed with age;
var ;
output out = summ_age ;
run;
*SORTING SUMMARY TABLE BY AGE;
proc sort data = summ_age; by age;
run;
*TRANSPOSING THE SORTED DATA WITH AGE AS OBS SEX VALUES AS COLUMNS;
PROC transpose data = summ_age out = hsi_age;
by age;
id sex;
var _freq_;
run;
data hsi_age;
set hsi_age;
retain grand_tot;
if _n_=1 then grand_tot=M+F; *the first row has the null age values, grand total by sex;
else do;
tot = sum(M,F);
PERCENTAGE=round((tot/grand_tot)*100,0.01); /*PERCENTAGE PER GROUP*/
output;
end;
run;
您也可以通过proc tabulate生成您正在寻找的内容，但这同样有效。
NOBS选项创建常规变量，您可以以与给定数据步骤中的任何其他变量相同的方式访问该变量(唯一的区别是该变量永远不会输出到目标数据集)。我猜你想做的事可以通过以下方式实现:
data out.hsi_age;
set out.hsi_age nobs=my_nobs_var;
tot = d+s+i;
PERCENTAGE=round((tot/my_nobs_var)*100,0.01); /*PERCENTAGE PER GROUP*/
run;