删除控制台.CancelKeyPress处理程序一次禁用任何未来处理

Question

我正在制作一个在控制台模式下工作的交互式基准测试程序，并希望能够通过按Ctrl+C或Ctrl+Break一次来中断当前的计算，而随后的按应该像往常一样，终止程序。但是，当当前没有执行计算时，第一次按Ctrl+C应该导致终止。

起初，这看起来像一个简单的任务。我创建了一个静态类，具有明显的EnableHandler()和DisableHandler()例程，以及一个处理程序函数，其行为依赖于先前的状态:如果已经请求中断，则只需退出并返回，否则设置arg.Cancel并引发中断请求标志。因此，当基准测试启动时，它启用处理程序，然后检查每个主周期上的中断标志;完成后，如果需要，它将禁用处理程序并将中断请求传播到最顶层的调用者。

然而，这种方法只工作一次:在处理程序第一次被删除之后(无论它是否被触发)，之后再次安装它不再起作用 -操作不会产生错误，但是处理程序在事件发生时永远不会接收控制。这是。net事件处理的预期行为吗?

在SO和其他论坛上有许多关于Console.CancelKeyPress的话题，但实际上没有一个人考虑删除处理程序，因此难怪他们没有遇到麻烦。尽管如此，在"如何多次使用ConsoleCancelEventHandler"中提到了一些类似的(?)问题，但该应用程序是一个复杂的GUI前端，用于按需启动几个外部控制台实用程序，并且该问题显然与第二次尝试添加处理程序时引发的显式异常有关，这不是我的情况。

已经被告知在各种。net版本中先前存在的与控制台操作相关的错误，如果这样的行为是异常的，由。net故障引起的，或者是特定于Visual Basic的，我不会感到惊讶(我不确定AddHandler和RemoveHandler是否在VB中。完全等同于c#中的+=和-=事件操作符)。我目前在Windows 7 x86-64上使用。net 4.5和Visual Basic 2012并安装了所有可用的更新。

作为一种解决方法，我实际上没有删除DisableHandler()例程中的处理程序，而是简单地切换一个标志:当这个标志被清除时，处理程序立即返回，就像没有安装一样。但是，这种方法在我看来很难看，我希望通过适当的方式解决问题，达到目的。

p。Chris Dunaway要求的当前代码:

' Usage example
Dim fAbort As Boolean = False
BreakHandler.Enable()
For Each oImplementation As Implementation In oCompetition.Implementations
    Benchmark(oImplementation)
    If BreakHandler.AbortRequested() Then fAbort = True : Exit For
Next
BreakHandler.Disable()
Return Not fAbort

Public Class BreakHandler
    Protected Shared AbortFlag As Boolean = False
    Protected Shared HandlerInstalled As Boolean = False
    Protected Shared HandlerEnabled As Boolean = False
    Public Shared ReadOnly Property AbortRequested() As Boolean
        Get
            If AbortFlag Then
                AbortFlag = False
                Return True
            Else
                Return False
            End If
        End Get
    End Property
    Public Shared Sub Enable()
        If HandlerEnabled Then Return
        If Not HandlerInstalled Then
            AddHandler Console.CancelKeyPress, AddressOf Handler
            HandlerInstalled = True
        End If
        HandlerEnabled = True
    End Sub
    Public Shared Sub Disable()
        AbortFlag = False
        If Not HandlerEnabled Then Return
        ' This is where the handler was removed originally.
        'RemoveHandler Console.CancelKeyPress, AddressOf Handler
        HandlerEnabled = False
    End Sub
    Protected Shared Sub Handler(ByVal sender As Object, ByVal args As ConsoleCancelEventArgs)
        If (Not HandlerEnabled) OrElse AbortFlag Then
            Return  ' Stand down, allow complete abortion.
        Else
            Console.Out.WriteLine("Will abort on next cycle. Press Break again to quit.")
            AbortFlag = True
            args.Cancel = True
        End If
    End Sub
End Class

Answer 1

是的，这是控制台类中的一个bug。存在于所有。net框架版本中，包括4.5.1。这是一个相当愚蠢的错误，当你第一次注册一个事件处理程序时，它会安装一个回调，这样Windows就会触发事件。当您删除事件处理程序并且没有其他事件处理程序时，它将卸载回调。但忘记重置内部"我已经安装回调"状态变量。所以当你再次调用AddHandler时，它不会重新安装回调。

你可以在connect.microsoft.com上报告这个bug，如果你不想花时间，请告诉我，我会处理的。

有一个愚蠢的解决方法，你只需要防止它再次卸载回调。这可以通过注册一个虚拟事件处理程序来实现。将这行代码放在Main()方法的顶部:

    AddHandler Console.CancelKeyPress, Sub(s, e)
                                       End Sub

当然你的变通方法也很好。请注意，您的代码还有其他问题，布尔变量不是同步对象。CancelKeyPress事件运行在另一个线程上，所以不能保证主线程可以看到值的变化。当您在发布版本中运行程序并使用x86抖动时，可能会出现故障。最低要求是将布尔变量声明为volatile，这样抖动就不会将变量存储在CPU寄存器中，而是总是从内存中重新加载它，而是VB。. NET语言没有相应的语法。你应该使用一个真正的同步对象，ManualResetEvent是合适的。