Delphi:拒绝其他进程访问文件

Question

如何拒绝其他进程访问（仅用于写入）文件？我会一直读/写一个文件。

我使用

FileOpen('c:1.txt', fmOpenReadWrite or fmShareDenyWrite)

但在（开始将文件加载到StringList）之后，我得到了错误

无法打开文件C:\1.txt。进程无法访问该文件，因为其他进程正在使用该文件。"

只有我打开了文件。

Answer 1

在这里，错误消息实际上有点误导。无法加载到字符串列表的原因是您已经以读/写方式打开了该文件。

如果检查TStrings.LoadfromFile:的实现

procedure TStrings.LoadFromFile(const FileName: string);
var
  Stream: TStream;
begin
  Stream := TFileStream.Create(FileName, fmOpenRead or fmShareDenyWrite);
  try
    LoadFromStream(Stream);
  finally
    Stream.Free;
  end;
end;

您可以看到它试图在"DenyWrite"条件下打开文件，但您已经在写入模式下打开了该文件。这就是它失败的原因。

您可以使用LoadFromStream来解决这个问题。

procedure TForm1.Button1Click(Sender: TObject);
var
  Stream: TStream;
begin
  Stream := TFileStream.Create(FileName, fmOpenRead or fmShareDenyNone);
  try
    Stringlist.LoadFromStream(Stream);
  finally
    Stream.Free;
  end;
end;

请注意，您需要使用fmShareDenyNone才能在这种情况下工作。再说一遍，你可能会重用从OpenFile获得的读/写句柄，可能会做这样的事情：

procedure TForm1.Button1Click(Sender: TObject);
var
  Stream: TStream;
  iPosition : Int64;
begin
  Stream := THandleStream.Create(FHandle); //FHandle is the read/write handle returned by OpenFile
  try
    iPosition := Stream.Position;
    Stream.Seek(0, soFromBeginning);
    Stringlist.LoadFromStream(Stream);
    Stream.Position := iPosition;
    //Restore stream position.
  finally
    Stream.Free;
  end;
end;

但请注意，这些方法可能有一些我不知道的"陷阱"。