如何在 XSLT 中对调用模板的结果求和

Question

我有一些XML，如下所示;

<risk>
  <driver driverId="2">
    <vehicleUse>M</vehicleUse>
  </driver>
  <driver driverId="3">
    <vehicleUse>F</vehicleUse>
  </driver>
  <driver driverId="4">
    <vehicleUse>I</vehicleUse>
  </driver>
</risk>

我正在使用XSLT（v1.0，.NET实现）将每个车辆使用转换为一个数字，然后获得这些数字的总和。车辆用途被翻译为M=3，F=2和I=1。增加的复杂性是，对于 ID 为 3 的驱动程序，这些值乘以 10，对于驱动程序 4 乘以 100。因此，在上面的示例中，总数将是 3 + 20 + 100 = 123。

我已经在我的 XSLT 文件中定义了一个模板，如下所示;

<xsl:template name="getVehicleUseScore">
  <xsl:param name="driverId" />
  <xsl:param name="vehicleUse" />
  <!-- Implementation left out for brevity -->
</xsl:template>

然后，XSLT 文件的其余部分将调用模板;

<xsl:template match="risk">
  <vehicleUseScore>
    <xsl:for-each select="driver">
      <xsl:call-template name="getVehicleUseScore">
        <xsl:with-param name="driverId" select="@driverId" />
        <xsl:with-param name="vehicleUse" select="vehicleUse" />
      </xsl:call-template>
    </xsl:for-each>
  </vehicleUseScore>
</xsl:template>
<xsl:template match="/">
  <xsl:apply-templates />
</xsl:template>

结果是我得到的文本"320100"，它只是 3、20 和 100 连接在一起，这至少证明了 getVehicleUseScore 模板有效。

我想将getVehicleUseScore的结果传递给sum（）函数，但我不知道怎么做。我尝试了以下方法;

<xsl:value-of select="sum(getVehicleUseScore(@driverId, vehicleUse))" />

但是XSLT编译器声明"getVehicleUseScore（）是一个未知的XSLT函数"。

有什么办法可以做到这一点吗？

Answer 1

下面是一个简短的 XSLT 1.0 方法来执行此操作：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:msxsl="urn:schemas-microsoft-com:xslt" exclude-result-prefixes="msxsl">
  <xsl:output omit-xml-declaration="yes" indent="yes"/>
  <xsl:strip-space elements="*"/>
 <xsl:template match="risk">
  <vehicleUseScore>
   <xsl:variable name="vrtfResult">
        <xsl:for-each select="driver">
          <xsl:call-template name="getVehicleUseScore">
            <xsl:with-param name="pdriverId" select="@driverId" />
            <xsl:with-param name="pvehicleUse" select="vehicleUse" />
          </xsl:call-template>
        </xsl:for-each>
    </xsl:variable>
    <xsl:value-of select="sum(msxsl:node-set($vrtfResult)/*)"/>
  </vehicleUseScore>
 </xsl:template>
 <xsl:template name="getVehicleUseScore">
  <xsl:param name="pdriverId" />
  <xsl:param name="pvehicleUse" />
  <score>
   <xsl:variable name="vValue" select=
   "(($pvehicleUse='M')*3 + ($pvehicleUse='F')*2 + ($pvehicleUse='I')*1)"/>
   <xsl:variable name="vFactor" select=
   "1 +(9*($pdriverId=3)) + (99*($pdriverId=4))"/>
   <xsl:value-of select="$vValue*$vFactor"/>
  </score>
 </xsl:template>
</xsl:stylesheet>

在提供的 XML 文档上应用此转换时：

<risk>
    <driver driverId="2">
        <vehicleUse>M</vehicleUse>
    </driver>
    <driver driverId="3">
        <vehicleUse>F</vehicleUse>
    </driver>
    <driver driverId="4">
        <vehicleUse>I</vehicleUse>
    </driver>
</risk>

生成所需的正确结果：

<vehicleUseScore>123</vehicleUseScore>

解释：

在变量中捕获模板的输出时，此变量的类型为 RTF（结果树片段），除非其内容包含任何节点（文本节点除外），否则 XPath 表达式无法导航其内容。

为此，需要对该变量调用供应商依赖扩展函数xxx:node-set()，以便它将 RTF 转换为常规树。

在这里，我们还使用了这样一个事实，即每当在算术表达式中遇到布尔值时，它都会转换为数字，并且根据定义：

number(true()) = 1

和

number(false()) = 0

Answer 2

另一种更

简洁但避免使用 node-set() 函数的方法（我喜欢尽可能避免使用专有函数，即使node-set()只是半专有的）是使用递归：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output omit-xml-declaration="yes" indent="yes"/>
  <xsl:template match="risk">
    <vehicleUseScore>
      <xsl:call-template name="sumDriverScores">
        <xsl:with-param name="drivers" select="driver" />
      </xsl:call-template>
    </vehicleUseScore>
  </xsl:template>
  <xsl:template name="sumDriverScores">
    <xsl:param name="drivers" />
    <xsl:if test="not($drivers)">
      <xsl:text>0</xsl:text>
    </xsl:if>
    <xsl:if test="$drivers">
      <xsl:variable name="currentValue">
        <xsl:call-template name="getVehicleUseScore">
          <xsl:with-param name="driverId" select="$drivers[1]/@driverId" />
          <xsl:with-param name="vehicleUse" select="$drivers[1]/vehicleUse" />
        </xsl:call-template>
      </xsl:variable>
      <xsl:variable name="sumRemainder">
        <xsl:call-template name="sumDriverScores">
          <xsl:with-param name="drivers" select="$drivers[position() > 1]" />
        </xsl:call-template>
      </xsl:variable>
      <xsl:value-of select="$currentValue + $sumRemainder"/>
    </xsl:if>
  </xsl:template>

  <xsl:template name="getVehicleUseScore">
    <xsl:param name="driverId" />
    <xsl:param name="vehicleUse" />
    <xsl:variable name="useFactor" select="translate($vehicleUse, 'MFI', '321')"/>
    <xsl:variable name="idFactor" 
                  select="1 + 9 * ($driverId = 3) +  99 * ($driverId = 4)"/>
    <xsl:value-of select="$useFactor * $idFactor"/>
  </xsl:template>
</xsl:stylesheet>

输出为：

<vehicleUseScore>123</vehicleUseScore>