XSLT if属性存在/else

Question

我对XSLT很陌生，因此我想知道检查属性是否存在的最佳实践是什么。我的XML看起来像这样：

<root>
    <languages>
        <lang id="EN">English<lang>
        <lang id="FR">French<lang>
        <lang id="DE">German</lang>
    </languages>
    <items>
        <item lang="EN">test 1</item>
        <item>test 2</item>
        <item lang="FR">item 3</item>
    </items>
</root>

请注意，"item"元素的"lang"属性是可选的。

现在，我想使用-循环遍历项目，同时检查它是否有"lang"-属性。如果是，我想使用ID获取整个字符串(例如EN->'English'(。如果属性没有设置，我希望它写"无语言集"或类似的内容。

现在我使用以下代码，但我在质疑自己是否不能以更有效的方式完成。

<xsl:for-each select="//root/items/item">
    <xsl:variable name="cur_lang" select="@lang" /> <!-- first I store the attr lang in a variable -->
    <xsl:choose>
        <xsl:when test="@lang"> <!-- then i test if the attr exists -->
            <xsl:value-of select="//root/languages/lang[@id=$cur_lang]" /> <!-- if so, parse the element value -->
        </xsl:when>
        <xsl:otherwise>
            No language set <!-- else -->
        </xsl:otherwise>
    </xsl:choose>
</xsl:for-each>

有什么建议/提示吗？

Answer 1

使用键可能更有效。您使用模板之外的顶级元素定义密钥

<xsl:key name="langByCode" match="lang" use="@id" />

然后在循环中，你可以简单地说

<xsl:when test="@lang"> <!-- then i test if the attr exists -->
   <xsl:value-of select="key('langByCode', @lang)" />
</xsl:when>

但一般来说，一种更自然的XSLT方法是使用模板匹配，而不是for-each和if:

<xsl:template match="item[@lang]">
  <xsl:value-of select="key('langByCode', @lang)" />
</xsl:template>
<xsl:template match="item">
  <xsl:text>No language set</xsl:text>
</xsl:template>

有了这些模板，你就可以进行<xsl:apply-templates select="/root/items/item" />，它会自动为每个项目选择合适的模板。规则是它将使用最特定的模板，因此item[@lang]用于那些具有lang属性的项，而普通的item用于那些没有属性的项。

第三种可能性是我在SO上学到的一个小技巧，将整个if/else检查放入一个XPath表达式中

<xsl:value-of select="
  substring(
    concat('No language set', key('langByCode', @lang)),
    1 + (15 * boolean(@lang))
  )" />

这里的技巧是，如果lang属性存在，则将boolean(@lang)视为数字时为1，如果不存在，则为0。如果有一个lang="EN"，那么我们构造一个字符串"No language setEnglish"，然后取从第16个字符开始的子字符串，即"English"。如果有nolang属性，我们构造字符串"No language set"(因为空节点集的字符串值是空字符串(，并取从第一个字符开始的子字符串(即整个字符串(。

你可以对其他属性使用同样的技巧，例如，假设我们有一个可选的颜色属性，如果没有"No color specified"，你可以用来做

<xsl:value-of select="substring(
   concat('No color specified', @color),
   1 + (18 * boolean(@color))
 )" />

Answer 2

如果您能够使用XSLT3.0，另一种选择是map(另一个有用的链接：map(。

XML输入(固定格式良好(

<root>
    <languages>
        <lang id="EN">English</lang>
        <lang id="FR">French</lang>
        <lang id="DE">German</lang>
    </languages>
    <items>
        <item lang="EN">test 1</item>
        <item>test 2</item>
        <item lang="FR">item 3</item>
    </items>
</root>

XSLT 3.0

<xsl:stylesheet version="3.0" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
    xmlns:map="http://www.w3.org/2005/xpath-functions/map"
    xmlns:xs="http://www.w3.org/2001/XMLSchema" extension-element-prefixes="xs map">
    <xsl:output indent="yes"/>
    <xsl:strip-space elements="*"/>
    <xsl:variable name="lang-map" as="map(xs:string, xs:string)" 
        select="map:new(
        for $lang in /*/languages/lang 
        return 
            map{$lang/@id := $lang/string()}
        )"/>
    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>
    <xsl:template match="languages"/>
    <xsl:template match="item[@lang and map:contains($lang-map,@lang)]">
        <item><xsl:value-of select="$lang-map(current()/@lang)"/></item>
    </xsl:template>
    <xsl:template match="item">
        <item>No language found.</item>
    </xsl:template>
</xsl:stylesheet>

输出

<root>
   <items>
      <item>English</item>
      <item>No language found.</item>
      <item>French</item>
   </items>
</root>