使用xslt解析xml时遇到的问题

Question

我正在尝试解析xml以生成html报告。xml中有问题的部分如给定的所示

<failure message="Management changes link count is not 3$HiHello" type="junit.framework.AssertionFailedError">junit.framework.AssertionFailedError: Management changes link count is not 3$HiHelloJI
at CustomProjects.CommonTemplates.verifyManagementChanges(Unknown Source)
at CustomProjects.EmersonTest.testEmerson_VerifyManagementChanges(Unknown Source)
</failure>

为解析这一点而编写的xslt是：

<xsl:choose>
        <xsl:when test="failure">
            <td>Failure</td>
            <td><xsl:apply-templates select="failure"/></td>
            <td><a href="ftp://10.32.1.66/seleniumScreenshotsFireFoxTest/{@name}.png" target="_blank">screenshot</a></td>
            <td><xsl:apply-templates select="failurelink"/></td>
        </xsl:when>
</xsl:choose>
<xsl:template match="failure">
  <xsl:call-template name="display-failures"/>
</xsl:template>
<xsl:template match="failurelink">
  <xsl:call-template name="display-failures-link"/>
</xsl:template>
<xsl:template name="display-failures">
  <xsl:param name="FailText" select="@message"/>
    <xsl:choose>
     <xsl:when test="not(@message)">N/A</xsl:when>
    <xsl:otherwise>
       <xsl:value-of select="substring-before($FailText,'$')"/>
    </xsl:otherwise>
</xsl:choose>
<!-- display the stacktrace -->
<code>
    <br/><br/>
    <xsl:call-template name="br-replace">
        <xsl:with-param name="word" select="."/>
    </xsl:call-template>
</code>
<!-- the later is better but might be problematic for non-21" monitors... -->
<!--pre><xsl:value-of select="."/></pre-->
</xsl:template>
<xsl:template name="display-failures-link">
<xsl:param name="linktext" select="@message"/>
 <xsl:choose>
    <xsl:when test="not(@message)">N/A</xsl:when>
    <xsl:otherwise>
       <xsl:value-of select="substring-after($linktext,'$')"/>
    </xsl:otherwise>
</xsl:choose>
<!-- display the stacktrace -->
<code>
    <br/><br/>
    <xsl:call-template name="br-replace">
        <xsl:with-param name="word" select="."/>
    </xsl:call-template>
</code>
<!-- the later is better but might be problematic for non-21" monitors... -->
<!--pre><xsl:value-of select="."/></pre-->
</xsl:template>

这里我从display failures模板中获得了所需的结果（$sign之前的字符串），但在调用display failures链接时，我一无所获。（应该得到$sign后面的字符串）。我不知道问题出在sunstring函数还是其他方面。请让我知道我在这里做错了什么。

非常感谢您的帮助。

Answer 1

这里的问题是，您试图在XPath failurelink上应用模板，但您没有一个名为<failurelink>的元素，所以这个apply-templates找不到任何东西。

<xsl:apply-templates select="failurelink"/>

在同一种元素上应用两个不同模板的一种方法是使用模式：

<xsl:template match="failure">
  <xsl:call-template name="display-failures"/>
</xsl:template>
<xsl:template match="failure" mode="link">
  <xsl:call-template name="display-failures-link"/>
</xsl:template>

然后，您应用模板的区域将更改为：

<td>Failure</td>
<td><xsl:apply-templates select="failure"/></td>
<td><a href="ftp://10.32.1.66/seleniumScreenshotsFireFoxTest/{@name}.png" target="_blank">screenshot</a></td>
<td><xsl:apply-templates select="failure" mode="link"/></td>

但在你的情况下，还有一个更好的方法。只需删除第二个模板，然后执行以下操作：

将整个<xsl:choose>替换为：

<xsl:apply-templates select="failure" />

将您列出的第一个模板替换为：

<xsl:template match="failure">
   <td>Failure</td>
   <td><xsl:call-template name="display-failures"/></td>
   <td><a href="ftp://10.32.1.66/seleniumScreenshotsFireFoxTest/{../@name}.png" target="_blank">screenshot</a></td>
   <td><xsl:call-template name="display-failures-link"/></td>
</xsl:template>

并删除您列出的第二个模板。