批处理文件以查找文件并运行程序

Question

好吧，我相信我正在用这个来推动批处理文件的限制。

我需要一个批处理文件，它将在文件中查找并找到"X"或"y"。如果找到任一，则运行程序。如果两者都未找到，请继续执行其余代码。它将查找的文件的扩展名为 .inf。它是使用记事本打开的。我什至不知道从哪里开始。任何帮助将不胜感激。:)

Answer 1

您可以使用 FINDSTR 同时搜索多个条目。像这样使用它：

FINDSTR "term1 term2 term3 ..."

如果至少找到一个术语，结果将是成功的。如有必要，请使用/I开关使搜索不区分大小写：

FINDSTR /I "term1 term2 term3 ..."

默认情况下，FINDSTR搜索stdin。将输入重定向到.inf文件，使其搜索文件：

FINDSTR /I "term1 term2 term3 ..." <file.inf

或者，您可以将文件名作为另一个参数：

FINDSTR /I "term1 term2 term3 ..." file.inf

在这两种情况下，输出会略有不同，但我知道您实际上不需要输出，而是搜索的结果，即它是成功还是失败。

若要检查结果，可以使用显式ERRORLEVEL测试，如下所示：

FINDSTR /I "term1 term2 term3 ..." file.inf
IF NOT ERRORLEVEL 1 yourprogram.exe

另一种语法是使用 ERRORLEVEL 系统变量，这可能比前者更简单：

IF %ERRORLEVEL% == 0 yourprogram.exe

执行相同操作的另一种方法是使用 && 运算符。此方法与ERRORLEVEL测试并不完全相同，但FINDSTR ERRORLEVEL测试和&&的工作方式相同，在这种情况下，&&方法的优点是更简洁：

FINDSTR /I "term1 term2 term3 ..." file.inf && yourprogram.exe

差不多就是这样了。最后需要注意的是，由于您可能实际上对FINDSTR的输出不感兴趣，因此您不妨通过将其重定向到NUL来抑制它，如下所示：

FINDSTR /I "term1 term2 term3 ..." file.inf >NUL && yourprogram.exe

Answer 2

尝试从此页面开始：

http://www.robvanderwoude.com/findstr.php

然后进一步参考批处理文件的基础知识：

http://www.robvanderwoude.com/batchfiles.php

Answer 3

FIND 和 FC 的组合可以做到这一点。

@echo off
REM try to find X
FIND /c "X" file.inf >test_isxfound.txt
REM what does it look like when I don't find a match
FIND /c "th1s$tringb3tt3rn0tbeinthisfile" file.inf >test_xnotfound.txt
REM then compare those results with the results where we know it wasn't found
FC test_xnotfound.txt test_isxfound.txt
REM then check to see if FC saw a difference
IF ERRORLEVEL 1 goto xisfound
ECHO *** X is not found
goto end
:xisfound
ECHO *** X is found
goto end
:end
del test_xnotfound.txt
del test_isxfound.txt