如何将有理数转换为"pretty"字符串？

Question

我想在十进制扩展中显示一些Rational值。 也就是说，与其显示3 % 4，我宁愿显示0.75。 我希望这个函数是 Int -> Rational -> String 型的。 第一个Int是指定最大小数位数，因为Rational扩展可能是非终止的。

Hoogle和Data.Ratio的黑线鳕对我没有帮助。 在哪里可以找到此功能？

Answer 1

你可以做到。不优雅，但可以完成工作：

import Numeric
import Data.Ratio
display :: Int -> Rational -> String
display n x = (showFFloat (Just n) $ fromRat x) ""

Answer 2

下面是一个不使用浮点数的任意精度解决方案：

import Data.Ratio
display :: Int -> Rational -> String
display len rat = (if num < 0 then "-" else "") ++ (shows d ("." ++ take len (go next)))
    where
        (d, next) = abs num `quotRem` den
        num = numerator rat
        den = denominator rat
        go 0 = ""
        go x = let (d, next) = (10 * x) `quotRem` den
               in shows d (go next)

Answer 3

重用库代码的任意精度版本：

import Data.Number.CReal
display :: Int -> Rational -> String
display digits num = showCReal digits (fromRational num)

我知道我以前见过一个函数，它以一种更容易检查的方式将有理数转换为数字（即，这很清楚数字开始重复的位置），但现在我似乎找不到它。无论如何，如果事实证明这是一种需要，写起来并不难;您只需编写通常的长除法算法并观察您已经完成的除法。

Answer 4

这是我

几周前写的。 您可以指定所需的小数位数（正确舍入），或者只传递Nothing在这种情况下，它将打印完整的精度，包括标记重复的小数。

module ShowRational where
import Data.List(findIndex, splitAt)
-- | Convert a 'Rational' to a 'String' using the given number of decimals.
-- If the number of decimals is not given the full precision is showed using (DDD) for repeating digits.
-- E.g., 13.7/3 is shown as "4.5(6)".
showRational :: Maybe Int -> Rational -> String
showRational (Just n) r =
    let d = round (abs r * 10^n)
        s = show (d :: Integer)
        s' = replicate (n - length s + 1) '0' ++ s
        (h, f) = splitAt (length s' - n) s'
    in  (if r < 0 then "-" else "") ++ h ++ "." ++ f
-- The length of the repeating digits is related to the totient function of the denominator.
-- This means that the complexity of computing them is at least as bad as factoring, i.e., it quickly becomes infeasible.
showRational Nothing r =
    let (i, f) = properFraction (abs r) :: (Integer, Rational)
        si = if r < 0 then "-" ++ show i else show i
        decimals f = loop f [] ""
        loop x fs ds =
            if x == 0 then
                ds
            else
                case findIndex (x ==) fs of
                    Just i  -> let (l, r) = splitAt i ds in l ++ "(" ++ r ++ ")"
                    Nothing -> let (c, f) = properFraction (10 * x) :: (Integer, Rational) in loop f (fs ++ [x]) (ds ++ show c)
    in  if f == 0 then si else si ++ "." ++ decimals f

Answer 5

import Data.List as L
import Data.Ratio
display :: (Integral i, Show i) => Int -> Ratio i -> String
display len rat = (if num < 0 then "-" else "") ++ show ip ++ "." ++ L.take len (go (abs num - ip * den))
  where
    num = numerator rat
    den = denominator rat
    ip  = abs num `quot` den
    go 0 = ""
    go x = shows d (go next)
      where
        (d, next) = (10 * x) `quotRem` den