批处理文件，以在没有外部文件的情况下用*替换输入

Question

我需要批处理文件来用*屏蔽输入，而不需要外部文件，我需要代码到（（（（写字母要快））），并且不使用*计算距离

（（（（如果有代码从批处理文件中提取外部文件，使外部文件用*和快速写入密码添加注释以查看代码）））

例如：

 @echo off
 set char=*
 set /p variable=Enter your password:
 set char=%variable%
 echo %char%
 pause

Answer 1

这是对您在上一个问题中得到的代码的"清理"。如果这对你来说不够快，那么你应该考虑不批量进行，并使用一些传统的工具。

@echo off
    setlocal enableextensions disabledelayedexpansion
rem Call the subroutine to get the password    
    call :getPassword password 
rem Echo what the function returns
    if defined password (
        echo You have typed [%password%]
    ) else (
        echo You have typed nothing
    )
rem End of the process    
    endlocal
    exit /b

rem Subroutine to get the password
:getPassword returnVar
    setlocal enableextensions disabledelayedexpansion
    set "_password="
    rem We need a backspace to handle character removal
    for /f %%a in ('"prompt;$H&for %%b in (0) do rem"') do set "BS=%%a"
    rem Prompt the user 
    set /p "=password ?:" <nul 
:keyLoop
    rem retrieve a keypress
    set "key="
    for /f "delims=" %%a in ('xcopy /l /w "%~f0" "%~f0" 2^>nul') do if not defined key set "key=%%a"
    set "key=%key:~-1%"
    rem handle the keypress 
    rem     if No keypress (enter), then exit
    rem     if backspace, remove character from password and console
    rem     else add character to password and go ask for next one
    if defined key (
        if "%key%"=="%BS%" (
            if defined _password (
                set "_password=%_password:~0,-1%"
                setlocal enabledelayedexpansion & set /p "=!BS! !BS!"<nul & endlocal
            )
        ) else (
            set "_password=%_password%%key%"
            set /p "=*"<nul
        )
        goto :keyLoop
    )
    echo(
    rem return password to caller
    if defined _password ( set "exitCode=0" ) else ( set "exitCode=1" )
    endlocal & set "%~1=%_password%" & exit /b %exitCode%