通过Xsl 1.0在xml中插入名称空间

Question

我的输入XML是这样的-

<Integer xmlns="www.maths.com" xmlns:abc="www.dateTypes.com" xmlns:def="www.calculations.com">
    <ID>A1</ID>
    <abc:Date>2005-11-20</abc:Date>
    <Type>12345</Type>
    <def:Maths>Multiply</def:Maths>
</Integer>

我想通过XSL 1.0将名称空间添加到具有相同前缀但具有不同值的根元素。我希望我的输出是-

<Integer xmlns="www.maths.com" xmlns:abc="www.dateTypes-2.0" xmlns:def="www.calculations-2.0">
    <ID>A1</ID>
    <abc:Date>2005-11-20</abc:Date>
    <Type>12345</Type>
    <def:Maths>Multiply</def:Maths>
</Integer>

请建议。

Answer 1

短方案:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:abc="www.dateTypes-2.0" xmlns:def="www.calculations-2.0">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>
 <xsl:variable name="vNS" select=
   "document('')/*/namespace::*[name()='abc' or name()='def']"/>
 <xsl:variable name="vDefNS" select="/*/namespace::*[not(name())]"/>
 <xsl:template match="*">
  <xsl:element name="{name()}">
       <xsl:copy-of select="$vDefNS"/>
       <xsl:apply-templates select="@*|node()"/>
  </xsl:element>
 </xsl:template>
 <xsl:template match="@*">
  <xsl:attribute name="{name()}">
   <xsl:value-of select="."/>
  </xsl:attribute>
 </xsl:template>
 <xsl:template match="*[name()=local-name()]">
     <xsl:element name="{name()}" namespace="{$vDefNS}">
       <xsl:copy-of select="$vNS"/>
       <xsl:apply-templates select="@*|node()"/>
     </xsl:element>
 </xsl:template>
</xsl:stylesheet>

当将此转换应用于以下XML文档时(与提供的文档相同，但添加了一个属性以使其更具代表性):

<Integer xmlns="www.maths.com"
 xmlns:abc="www.dateTypes.com" xmlns:def="www.calculations.com">
    <ID>A1</ID>
    <abc:Date>2005-11-20</abc:Date>
    <Type abc:x="1">12345</Type>
    <def:Maths>Multiply</def:Maths>
</Integer>

生成所需的正确结果:

<Integer xmlns="www.maths.com" xmlns:abc="www.dateTypes-2.0" xmlns:def="www.calculations-2.0">
   <ID>A1</ID>
   <abc:Date>2005-11-20</abc:Date>
   <Type abc:x="1">12345</Type>
   <def:Maths>Multiply</def:Maths>
</Integer>

Answer 2

这应该能奏效:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                xmlns:abc="www.dateTypes-2.0" xmlns:def="www.calculations-2.0"
                xmlns:oldabc="www.dateTypes.com" xmlns:olddef="www.calculations.com"
                xmlns:maths="www.maths.com"
                exclude-result-prefixes="oldabc olddef maths">
  <xsl:output method="xml" indent="yes"/>
  <xsl:template match="oldabc:*">
    <xsl:element name="abc:{local-name()}">
      <xsl:apply-templates select="@* | node()" />
    </xsl:element>
  </xsl:template>
  <xsl:template match="olddef:*">
    <xsl:element name="def:{local-name()}">
      <xsl:apply-templates select="@* | node()" />
    </xsl:element>
  </xsl:template>
  <xsl:template match="@oldabc:*">
    <xsl:attribute name="abc:{local-name()}">
      <xsl:value-of select="."/>
    </xsl:attribute>
  </xsl:template>
  <xsl:template match="@olddef:*">
    <xsl:attribute name="def:{local-name()}">
      <xsl:value-of select="." />
    </xsl:attribute>
  </xsl:template>
  <xsl:template match="@* | text()">
    <xsl:copy>
      <xsl:apply-templates select="@* | node()"/>
    </xsl:copy>
  </xsl:template>
  <xsl:template match="*">
    <xsl:element name="{name()}" namespace="{namespace-uri()}">
      <xsl:apply-templates select="@* | node()"/>
    </xsl:element>
  </xsl:template>
  <xsl:template match="/maths:Integer">
    <Integer xmlns="www.maths.com" xmlns:abc="www.dateTypes-2.0" xmlns:def="www.calculations-2.0">
      <xsl:apply-templates select="@* | node()"/>
    </Integer>
  </xsl:template>
</xsl:stylesheet>

当上面的XSLT在示例输入上运行时，它产生预期的结果:

<Integer xmlns="www.maths.com" xmlns:abc="www.dateTypes-2.0" xmlns:def="www.calculations-2.0">
  <ID>A1</ID>
  <abc:Date>2005-11-20</abc:Date>
  <Type>12345</Type>
  <def:Maths>Multiply</def:Maths>
</Integer>