冻结多个变量

Question

我试图编写一个谓词，该谓词接受列表并将其转换为平衡树。我的代码如下所示:

/* make_tree(list, tree)
 *
 *    list: list with the elements of the tree in prefix order
 *    tree: balanced tree of the elements in the list
 * 
 */
make_tree([], empty).
make_tree([H|T], node(L, R, H)):-
    split_half(T, T1, T2),
    make_tree(T1, L),
    make_tree(T2, R).
/* split_half(list, first, second)
 * 
 *    list: list with n elements
 *    first: list with first (n // 2) elements
 *    second: list with last (n - n // 2) elements
 *
 */
split_half(L, L1, L2):-
   split_half(L, L, L1, L2).
split_half(L, [], [], L):- !.
split_half(L, [_], [], L):- !.
split_half([H|T], [_,_|Acc], [H|L1], L2):-
   split_half(T, Acc, L1, L2).

，这样调用就可以了:

?- make_tree([1,2,3], Tree).
Tree = node(node(empty, empty, 2), node(empty, empty, 3), 1).

，但是当以其他方式调用它时不起作用，例如:

?- make_tree(L, node(node(empty, empty, 2), node(empty, empty, 3), 1)).
false.

这不是必要的，但我还是接受了挑战，让它双向工作。我想用freeze/2对split，比如freeze(T2, split(T, T1, T2))，来解决这个问题这使得?- make_tree(L, node(node(empty, empty, 2), node(empty, empty, 3), 1)).有效，但原来的想法不再有效了。所以实际上我要找的是某种freeze/2，它可以做freeze((T;T2), split(T, T1, T2))那样的事情。有人知道怎么解决这个问题吗?

Thanks in advance

Answer 1

您很可能正在寻找when/2。它由SICStus Prolog(手册页)和sw -Prolog(手册页)提供。

样本使用:

myfreeze1(V,Goal) :-
   when(nonvar(V),Goal).
myfreeze2(V1,V2,Goal) :-
   when((nonvar(V1);nonvar(V2)),Goal).

Answer 2

这是一个不使用协同调度的方法。其思想是首先在树和它的元素的数之间建立关系，这些元素由一个列表表示。请注意，我们首先不查看具体元素(_)，因为我们还不知道它们的顺序。元素的数量固定了，我们可以像以前一样进行，但不进行切割。

list_tree(Xs, Tree) :-
   phrase(tree_els(Tree), Xs),
   make_tree(Xs, Tree).
tree_els(empty) -->
   [].
tree_els(node(L, R, _)) -->
   [_],
   tree_els(L),
   tree_els(R).

由于性能原因，这个版本可能会从协程中获益。毕竟tree_els/1对于所有可能的树都是成功的，不管它们是否平衡。