在Fortran 90中计算两个向量的叉积

最佳做法是将过程（子例程和函数）放在一个模块中，然后从主程序或其他过程中"使用"该模块。您不需要"使用"同一模块的其他过程中的模块。这将使过程的接口显式，以便调用程序或过程"知道"参数的特性。。。它允许编译器检查双方参数之间的一致性。。。呼叫者和被呼叫者。。这消除了很多错误。

在语言标准之外，但在实践中是必要的：如果你使用一个文件，请将模块放在使用它的主程序之前。否则编译器将不知道它。所以：

module my_subs
implicit none
contains
FUNCTION cross(a, b)
  INTEGER, DIMENSION(3) :: cross
  INTEGER, DIMENSION(3), INTENT(IN) :: a, b
  cross(1) = a(2) * b(3) - a(3) * b(2)
  cross(2) = a(3) * b(1) - a(1) * b(3)
  cross(3) = a(1) * b(2) - a(2) * b(1)
END FUNCTION cross
end module my_subs

PROGRAM crosstest
  use my_subs
  IMPLICIT NONE
  INTEGER, DIMENSION(3) :: m, n
  INTEGER, DIMENSION(3) :: r
  m= [ 1, 2, 3 ]
  n= [ 4, 5, 6 ]
  r=cross(m,n)
  write (*, *) r
END PROGRAM crosstest

这是一个迟来的答案，但由于我偶然发现了这个问题，而且还没有真正的解释为什么会出现错误，我想我应该为其他偶然发现这个问题的人添加一个解释：

在程序中，定义一个名为cross的数组，该数组的级别为1。然后调用您进一步定义的cross函数。由于r=cross(m,n)0函数没有显式接口（请参见M.S.B.的答案），编译器目前还不知道它。它所知道的是您声明的数组。如果编写r = cross(m, n)，编译器会认为您想要访问数组cross的位置（m，n）处的元素。由于此数组的秩为1，但您提供了两个参数，因此会得到错误

rank mismatch in array reference at (1) (2/1)

这意味着当编译器期望提供两个坐标时，您提供了两个坐标。

您可以将程序中使用的子例程放在程序中的contains关键字之后。这消除了创建模块或添加接口定义的需要。

PROGRAM crosstest
  IMPLICIT NONE
  INTEGER, DIMENSION(3) :: m, n
  INTEGER, DIMENSION(3) :: r
  m = (/1, 2, 3/)
  n = (/4, 5, 6/)
  r = cross(m,n)
  print *, r
CONTAINS
PURE FUNCTION cross(a, b)
  INTEGER, DIMENSION(3) :: cross
  INTEGER, DIMENSION(3), INTENT(IN) :: a, b
  cross(1) = a(2) * b(3) - a(3) * b(2)
  cross(2) = a(3) * b(1) - a(1) * b(3)
  cross(3) = a(1) * b(2) - a(2) * b(1)
END FUNCTION cross
END PROGRAM crosstest