为什么这些idneitcal QB计算产生的值略有不同

Question

所以，我试图将一些非常古老的工程分析QBasic 4.5代码移植到C中。我试图准确匹配结果，但我发现我不太理解QB是如何计算的。

例如，这两条线

DIM a AS SINGLE
DIM d2 AS SINGLE
DIM e2 AS SINGLE
a = 32.174
d2 = 1! / (2! * 32.174 * 144!)
e2 = 1! / (2! * a! * 144!)

d2变为1.07920125E-4(浮点0x38e2532d(

e2变为1.0792013E-4(浮点0x38e2532e(

它们有着细微的不同。有人能帮我理解为什么吗？非常感谢。

Answer 1

d2和e2都得到了相同的输出，即使是在值的原始字节表示方面也是如此。以下是一些注释输出：

# Calculation results
d2: 38 E2 53 2E
e2: 38 E2 53 2E
 1.079201E-04 =  1.079201E-04
# Result of changing the last byte (some mantissa bits) to alter the value,
# proving they're not equal
d2: 38 E2 53 2F
e2: 38 E2 53 2E
 1.079201E-04 <> 1.079201E-04
# Result above may just be luck. This result alters the first byte
# (some exponent bits) to prove that the intended bits were altered.
d2: 39 E2 53 2E
e2: 38 E2 53 2E
 4.316805E-04 <> 1.079201E-04

代码：

DIM a AS SINGLE
DIM SHARED d2 AS SINGLE
DIM SHARED e2 AS SINGLE
a = 32.174
d2 = 1! / (2! * 32.174 * 144!)
e2 = 1! / (2! * a! * 144!)
' Print the hex representation of the bytes
' and show they're initially equal.
CALL printHex
PRINT
' Change the last byte of the mantissa by 1 bit.
' Show that doing this makes the two values unequal.
DEF SEG = VARSEG(d2)
    POKE VARPTR(d2), PEEK(VARPTR(d2)) + 1
DEF SEG
CALL printHex
PRINT
' Show that the correct byte was poked by reverting mantissa change and
' altering exponent.
DEF SEG = VARSEG(d2)
    POKE VARPTR(d2), PEEK(VARPTR(d2)) - 1
    POKE VARPTR(d2) + 3, PEEK(VARPTR(d2) + 3) + 1
DEF SEG
CALL printHex
SUB printHex
    'SHARED variables used:
    '  d2, e2
    DIM d2h AS STRING * 8, e2h AS STRING * 8
    ' Get bytes of d2 and e2, storing them as hexadecimal values
    ' in d2h and e2h.
    DEF SEG = VARSEG(d2)
        MID$(d2h, 1) = hexByte$(PEEK(VARPTR(d2) + 3))
        MID$(d2h, 3) = hexByte$(PEEK(VARPTR(d2) + 2))
        MID$(d2h, 5) = hexByte$(PEEK(VARPTR(d2) + 1))
        MID$(d2h, 7) = hexByte$(PEEK(VARPTR(d2)))
    DEF SEG = VARSEG(e2)
        MID$(e2h, 1) = hexByte$(PEEK(VARPTR(e2) + 3))
        MID$(e2h, 3) = hexByte$(PEEK(VARPTR(e2) + 2))
        MID$(e2h, 5) = hexByte$(PEEK(VARPTR(e2) + 1))
        MID$(e2h, 7) = hexByte$(PEEK(VARPTR(e2)))
    DEF SEG
    ' Print the bytes, separating them using spaces.
    PRINT "d2: "; MID$(d2h, 1, 2); " "; MID$(d2h, 3, 2); " ";
    PRINT MID$(d2h, 5, 2); " "; MID$(d2h, 7, 2)
    PRINT "e2: "; MID$(e2h, 1, 2); " "; MID$(e2h, 3, 2); " ";
    PRINT MID$(e2h, 5, 2); " "; MID$(e2h, 7, 2)
    ' Print whether d2 is equal to e2.
    IF d2 = e2 THEN
        PRINT d2; "= "; e2
    ELSE
        PRINT d2; "<>"; e2
    END IF
END SUB
FUNCTION hexByte$ (b%)
    ' Error 5 is "Illegal function call".
    ' This can only happen if b% is outside the range 0..255.
    IF b% < 0 OR b% > 255 THEN ERROR 5
    ' MID$("0" + HEX$(15), 2 + (-1)) => MID$("0F",  1) => "0F"
    ' MID$("0" + HEX$(16), 2 + ( 0)) => MID$("010", 2) => "10"
    hexByte$ = MID$("0" + HEX$(b%), 2 + (b% < 16))
END FUNCTION

编辑

正如@BlackJack在评论中解释的那样，你注意到的效果似乎发生在编译文件时。由于这是给出的线索，我在DOSBox中使用了CodeView调试器，下面是简化的结果：

5:      a = 32.174
057D:0030 C70636002DB2   MOV       Word Ptr [0036],B22D
057D:0036 C70638000042   MOV       Word Ptr [0038],4200
6:      d2 = 1! / (2! * 32.174 * 144!)
057D:003C C7063A002D53   MOV       Word Ptr [003A],532D
057D:0042 C7063C00E238   MOV       Word Ptr [003C],38E2
7:      e2 = 1! / (2! * a! * 144!)
057D:0048 CD35065000     FLD       DWord Ptr [0050]; 00 CB 21 CD
057D:004D CD34363600     FDIV      DWord Ptr [0036]; 42 00 B2 2D
057D:0052 CD351E3E00     FSTP      DWord Ptr [003E]; e2 = result
057D:0057 CD3D           FWAIT

BASIC编译器(BC.EXE(将d2的赋值简化为浮点常量的简单赋值(即，它评估表达式本身，并将代码优化为单个赋值，而不是执行您指定的所有操作(。然而，对e2的赋值并没有那么简单，因为它包含一个非常量表达式a!。

为了解决这个问题并试图保持尽可能多的精度，它将1 / (2 * a * 144)更改为数学上等效的(1 / 288) / a，并且1 / 288的近似值存储在偏移量0x0050处，这就是为什么FLD最终加载了该偏移量。加载该SINGLE值后，它将其除以a的值(偏移量0x0036(，并将结果存储在e2中(偏移量0x003E(。您可以使用CONST a = 32.174使e2的赋值与d2的赋值相同，但不能更改其值。

现在可能有人想知道为什么只有在编译时才会发生这种情况，而不是在IDE中，我真的不知道。我的最佳猜测是，IDE在FP堆栈上保留尽可能多的浮点值以保持精度，因此它不使用a的32位舍入值，而是使用FP堆栈上已经存储的现有80位值(如果它仍然存储在那里的话(。通过这种方式，精度损失较小，因为在FP堆栈之外存储80位值需要四舍五入到最接近的32位或64位值，具体取决于指定存储值的位置。当然，如果出于某种原因，FP堆栈上需要8个以上的值，则需要将其中一个值交换出去，为另一个值腾出空间，精度损失最终会显现出来。

@BlackJack还指出，IDE正在解释代码，而不是通过优化进行编译，这可能是代码在IDE中运行时字节表示相同，但在编译版本中不同的原因。也就是说，d2和e2的计算都以完全相同的方式执行，而不是像BC.EXE那样将d2的计算优化为单个值。

无论如何，您可能不会在C代码中注意到这一点，因为在优化方面，即使没有SSE2等现代浮点技术的帮助，您的现代编译器也比BC.EXE智能得多，可以使用更多的内存。

Answer 2

您使用的是哪个QB版本？您是如何打印或输出变量d2和e2的？

当我在DOSBox 0.74中的QuickBASIC 4.5中尝试您的程序时，我没有得到不同的值，当我PRINT时，d2和e2是相同的。

a =  32.174
d2 =  1.079201E-04 
e2 =  1.079201E-04 

exlamation标记操作符会将其类型转换为SINGLE(单精度，4字节(，因此它与AS SINGLE相同。也许您的行d2 = 1! /..中的值32.174正在以某种方式被类型转换为DOUBLE？