链接数据 - 在 SPARQL 查询中"or"

Question

我不太明白为什么在SPARQL中他们没有实现基本的逻辑运算符。然而，在大多数情况下，可以通过多种方法获得相同的结果。

这个问题的目的是快速参考可以替代"或"声明。

这是我能想到的:

1) UNION

例句:

SELECT * WHERE
{  { ?s :propA ?o } UNION { ?s :propB ?o }  }

—通常不适合，因为

会变得非常冗长，因为

SELECT * WHERE { 
    { GRAPH ?g {?s ?p ?o. ?o ?pp ?data1}} UNION 
    { GRAPH ?g {?s ?p ?o. ?o ?pp ?data2}}
} 

不能作为

使用

SELECT * WHERE { 
    GRAPH ?g {
       ?s ?p ?o. 
       {?o ?pp ?data1} UNION 
       {?o ?pp ?data2} 
    }
 }

(至少不是星狗)

2) FILTER

例句:

SELECT * WHERE
    { 
        ?s ?p ?o.
        FILTER (?p = :propA || ?p = :propB )
    }

还有其他想法吗?

Answer 1

我不完全确定为什么你说SPARQL不提供'基本逻辑运算符'，因为你自己的例子清楚地表明它提供:它提供逻辑或(||)和逻辑与(&&)作为FILTER条件的一部分，并使用UNION的析取图模式(当然，合取图模式不需要特殊的语法)。

OR类结构的其他变体也是可能的。对于"这个特定的值必须是这些可能性之一"这样的查询，您可以使用set membership操作符IN:

SELECT * 
WHERE { 
    ?s ?p ?o.
    FILTER (?p IN (:propA, :propB, :propC ) )
}

对于这种模式，您也可以使用VALUES子句:

SELECT * 
WHERE {
    VALUES ?p { :propA :propB :propC } 
    ?s ?p ?o.
}

Update我忘了一个，可能是最简单的。对于像您这样的查询，您正在寻找属性名称的几个替代方案，您实际上也可以使用属性路径表达式，如下所示:

SELECT * 
WHERE {
    ?s :propA|:propB|:propC ?o.
}

Answer 2

如果您想要跟踪哪个谓词导致哪个对象，那么这是"OR"的通用解决方案:

SELECT DISTINCT ?s ?o1 ?o2 
WHERE {
  {
     ?s p1 ?o1 .
     OPTIONAL
     {
        ?s p2 ?o2 .
     }
  } 
  UNION 
  {
     ?s p2 ?o2 .
     OPTIONAL
     {
        ?s p1 ?o1 .
     }
  }
}