作为MPI窗口基指针的派生数据类型

Question

我想使用派生数据类型与MPI3共享内存。给定以下派生数据类型:

type ::pve_data
  type(pve_data), pointer :: next => NULL()
  real*8        , pointer :: array(:) => NULL()
end type pve_data

初始化:

type(pve_data) :: pve_grid
allocate(pve_grid%array(10))
pve_grid%array = 0.0d0

在用pve_grid做了一些计算之后，我想用MPI_WIN_ALLOCATE_SHARED创建一个共享内存窗口，其基础应该是pve_grid。(也许MPI_WIN_CREATE_DYNAMIC将是一个替代方案，但我需要通过共享内存的性能)

1)到目前为止，我只是使用原始数据类型或数组作为窗口创建的基指针。派生数据类型也可以用作基指针吗?或者我是否需要为派生数据类型的每个组件创建一个窗口，这是一个原始变量?

2)是否有可能使用已经"使用"的变量(pve_grid在这种情况下)作为基指针?或者我需要使用新的pve_data作为基指针，并将pve_grid的值复制到它?

编辑我知道，使用openmp方法而不是MPI共享内存会更容易。但是我想尝试一种只使用mpi的方法，来提高我的mpi能力。

EDIT2 (05.09.16)我取得了一些进展，能够使用共享内存，其中基指针是一个简单的整数变量。但是，当我想使用派生数据类型作为窗口创建的基指针时，我仍然有一个问题(为了测试目的，我改变了它的定义-参见sharedStructMethod)。下面的法郎)。编译器和执行不会抛出任何错误…远程访问对派生数据类型组件没有任何影响:写入操作显示的是父组件初始化的旧值。后面的代码显示了我的当前状态。我使用了在执行期间生成新进程的可能性:父进程创建窗口，子进程在其上执行更改。我希望产卵过程不会麻烦调试的努力，我刚刚为我的项目添加了它。(下次我将更改real*8以符合标准)。

派生数据类型的声明(sharedStructMethod.f90)

  module sharedStructMethod
      REAL*8, PARAMETER      :: prec=1d-13
      INTEGER, PARAMETER     :: masterProc = 0
      INTEGER, PARAMETER     :: SLAVE_COUNT = 2
      INTEGER, PARAMETER     :: CONSTSIZE = 10
      !Struct-Definition    
         type :: vertex
            INTEGER, Dimension(3) :: coords
         end type vertex
         type :: pve_data
            real(kind(prec)), pointer   :: intensity(:) => NULL()
            logical, pointer            :: flag => NULL()
            type(vertex), pointer       :: vertices(:) => NULL()
         end type pve_data
      end module sharedStructMethod

用户执行的父进程(sharedStruct.f90)的声明。

      PROGRAM sharedStruct
     USE, INTRINSIC :: ISO_C_BINDING, ONLY : C_PTR, C_F_POINTER
     USE mpi
     USE sharedStructMethod
     IMPLICIT NONE
     type(pve_data) :: pve_grid
     integer        :: ierror
     integer        :: myRank, numProcs
     INTEGER        :: childComm
     INTEGER        :: childIntracomm
     integer        :: i
     INTEGER(KIND=MPI_ADDRESS_KIND) :: memSize
     INTEGER                        :: dispUnit
     TYPE(C_PTR)                    :: basePtr
     INTEGER                        :: win
     TYPE(pve_data), POINTER        :: shared_data
     call MPI_INIT(ierror)
     memSize = sizeof(pve_grid)
     dispUnit = 1
     CALL MPI_COMM_SPAWN("sharedStructWorker.x", MPI_ARGV_NULL, SLAVE_COUNT, MPI_INFO_NULL, masterProc,MPI_COMM_SELF, childComm,MPI_ERRCODES_IGNORE, ierror);
     CALL MPI_INTERCOMM_MERGE(childComm, .false., childIntracomm, ierror)
     CALL MPI_WIN_ALLOCATE_SHARED(memSize, dispUnit, MPI_INFO_NULL, childIntracomm, basePtr, win, ierror)
     CALL C_F_POINTER(basePtr, shared_data)
     CALL MPI_WIN_LOCK(MPI_LOCK_EXCLUSIVE, masterProc,0,win,ierror)
     allocate(shared_data%intensity(CONSTSIZE))
     allocate(shared_data%vertices(CONSTSIZE))
     allocate(shared_data%flag)
     shared_data%intensity = -1.0d0
     DO i =1,CONSTSIZE
        shared_data%vertices(i)%coords(1) = -1
        shared_data%vertices(i)%coords(2) = -2
        shared_data%vertices(i)%coords(3) = -3
     END DO
     shared_data%flag = .true.
     CALL MPI_WIN_UNLOCK(masterProc, win, ierror)
     CALL MPI_BARRIER(childIntracomm, ierror)
     CALL MPI_BARRIER(childIntracomm, ierror)
     WRITE(*,*) "After: Flag ",shared_data%flag,"intensity(1): ",shared_data%intensity(1)
     call mpi_finalize(ierror)
  END PROGRAM sharedStruct

最后但并非最不重要的是:子进程的声明，它在运行时由父进程自动生成，并更改窗口内容(sharedStructWorker.f90)

PROGRAM sharedStructWorker
USE mpi
  USE, INTRINSIC :: ISO_C_BINDING, ONLY : C_PTR, C_F_POINTER
  USE sharedStructMethod
  IMPLICIT NONE
  INTEGER                   :: ierror
  INTEGER                   :: myRank, numProcs
  INTEGER                   :: parentComm
  INTEGER                   :: parentIntracomm
  TYPE(C_PTR)               :: pveCPtr
  TYPE(pve_data), POINTER   :: pve_gridPtr
  INTEGER                   :: win
  INTEGER(KIND=MPI_ADDRESS_KIND)    :: sizeOfPve
  INTEGER                   :: dispUnit2
  CALL MPI_INIT(ierror)
  CALL MPI_COMM_GET_PARENT(parentComm, ierror)
  CALL MPI_INTERCOMM_MERGE(parentComm, .true., parentIntracomm, ierror)
  sizeOfPve = 0_MPI_ADDRESS_KIND
  dispUnit2 = 1
  CALL MPI_WIN_ALLOCATE_SHARED(sizeOfPve,dispUnit2, MPI_INFO_NULL, parentIntracomm, pveCPtr, win, ierror)
  CALL MPI_WIN_SHARED_QUERY(win, masterProc, sizeOfPve, dispUnit2, pveCPtr, ierror)
  CALL C_F_POINTER(pveCPtr, pve_gridPtr)
  CALL MPI_BARRIER(parentIntracomm, ierror)
  CALL MPI_WIN_LOCK(MPI_LOCK_EXCLUSIVE,masterProc,0,win,ierror)
  pve_gridPtr%flag = .false.
  pve_gridPtr%intensity(1) = 42
  CALL MPI_WIN_UNLOCK(masterProc, win, ierror)
  CALL MPI_BARRIER(parentIntracomm, ierror)
  CALL MPI_FINALIZE(ierror)
  END PROGRAM sharedStructWorker

编译:

mpiifort   -c  sharedStructMethod.f90
mpiifort   -o  sharedStructWorker.x sharedStructWorker.f90 sharedStructMethod.o
mpiifort   -o  sharedStruct.x sharedStruct.f90 sharedStructMethod.o

这是正确的方法，还是我需要为派生数据类型pve_data的每个组件创建一个具有自己窗口的共享内存块，这只是一个指针?谢谢你的帮助!

EDIT 10/09/2016解决方案:在评论中解释。解决这个问题的一种方法是为每个组件生成一个窗口，父组件和子组件都在该窗口上工作。对于更复杂的派生数据类型，这很快就会变得繁琐，但似乎没有别的选择。

Answer 1

我认为这主要涵盖在这里:MPI Fortran代码:如何通过openMP共享节点上的数据?

因此，在1)中，您可以使用Fortran派生类型的基指针。然而，对于2)的答案是MPI_Win_alloc_shared 返回存储给您——您不能重用现有的存储。如果你有一个链表，我不知道如何将其转换为共享窗口，甚至在原则上。为了能够使用返回的存储空间，拥有一个pve_data对象数组会简单得多——您必须将它们连续存储在返回的数组中，因此链接它们似乎不会增加任何有用的东西。

我可能误解了——如果你只希望列表的头在窗口中可以远程访问，那么这应该是可以的