如果不存在在目标文件夹中，则从源文件夹中复制电子邮件

Question

我正在使用Visual Studio来构建一个复制电子邮件。

根据SentOn/ReceivedTime，该条件是检查目标文件夹中不存在的源文件夹中的那些电子邮件。

我尝试了以下代码，但它给了我一个错误System.OutOfMemoryException Out of memory or system resources。

Sub CopyMail(SourceFolder As Outlook.Folder, DestinationFolder As Outlook.Folder)
    Dim sMail As Object
    Dim dMail As Object
    Dim MailC As Object
    For Each sMail In SourceFolder.Items
        For Each dMail In DestinationFolder.Items
            If sMail.SentOn <> dMail.SentOn Then
                MailC = sMail.Copy
                MailC.Move(DestinationFolder)
            End If
        Next
    Next
End Sub

Answer 1

嵌套循环中存在一个逻辑错误 - 对于目标文件夹中的每个项目，您从源文件夹中复制所有不匹配文件夹。

这是一种应起作用的方法（未经测试）。它在VBA中：我的vb.net不好，无论如何您都标有VBA ...

Sub CopyMail(SourceFolder As Outlook.Folder, DestinationFolder As Outlook.Folder)
    Dim sMail As Object
    Dim dMail As Object
    Dim MailC As Object
    Dim dictSent As New Scripting.dictionary, i As Long
    'get a list of all unique sent times in the
    '  destination folder
    For Each dMail In DestinationFolder.Items
        dictSent(dMail.SentOn) = True
    Next
    'loop through the source folder and copy all items where
    '  the sent time is not in the list
    For i = SourceFolder.Items.Count To 1 Step -1
        Set sMail = SourceFolder.Items(i)
        If Not dictSent.Exists(sMail.SentOn) Then
            Set MailC = sMail.Copy        'copy and move
            MailC.Move DestinationFolder
            dictSent(sMail.SentOn) = True 'add to list
        End If
    Next i
End Sub