访问 VBA 如何根据多选列表框中的选择筛选记录集

Question

我正在尝试使用 OpenForm 函数根据多选列表框中的选择进行过滤。 正确的语法是什么，或者有更好的方法吗？为了举例说明，我们说：

列表框具有 Ken、Mike 和 Sandy 选项。

汽车有选项Car1，Car2和Car 3。所有汽车都归该列表框中的 1 个或多个人所有。

如果从列表框中选择了某人，我想打开一个包含所选人员拥有的汽车的表单。

谢谢！

Answer 1

好的 所以我想出了一个办法：

1. 创建字符串以保存查询
2. 使用 For 循环根据所选的每个项填充字符串
3. 将该字符串作为筛选器放在 OpenForm 命令中。

这是我习惯的特定代码。我在原始帖子中的示例使用了汽车和人，但我的实际上下文是不同的：估算器和工作分工是过滤器。如果您是有相同问题的人，请告诉我，如果您对此有任何疑问！因为如果不了解我到底要完成什么，这可能会令人困惑。

Dim strQuery As String
Dim varItem As Variant
'query filtering for estimators and division list box selections
strQuery = ""
If Me.EstimatorList.ItemsSelected.Count + Me.DivisionList.ItemsSelected.Count > 0 Then
    For Each varItem In Me.EstimatorList.ItemsSelected
        strQuery = strQuery + "[EstimatorID]=" & varItem + 1 & " OR "
    Next varItem
    If Me.EstimatorList.ItemsSelected.Count > 0 And Me.DivisionList.ItemsSelected.Count > 0 Then
        strQuery = Left(strQuery, Len(strQuery) - 4)
        strQuery = strQuery + " AND "
    End If
    For Each varItem In Me.DivisionList.ItemsSelected
        strQuery = strQuery + "[DivisionID]=" & varItem + 1 & " OR "
    Next varItem
    strQuery = Left(strQuery, Len(strQuery) - 4)
End If

Answer 2

使用 JOIN 函数获取更简洁、更安全的代码

当您发现自己使用分隔符（如"，"AND"OR"）反复构建增量SQL字符串时，可以方便地集中生成数组数据，然后使用VBA Join（array，分隔符）函数。

如果感兴趣的键位于数组中，则用户从多选列表框中选择为表单筛选器属性生成 SQL WHERE 片段可能如下所示：

Private Sub lbYear_AfterUpdate()
    Dim strFilter As String
    Dim selction As Variant
    selction = ListboxSelectionArray(lbYear, lbYear.BoundColumn)
    If Not IsEmpty(selction) Then
        strFilter = "[Year] IN (" & Join(selction, ",") & ")"
    End If
    Me.Filter = strFilter
    If Not Me.FilterOn Then Me.FilterOn = True 
End Sub

从选定的 lisbok 行中选取任何列数据的泛型函数可能如下所示：

'Returns array of single column data of selected listbox rows
'Column index 1..n
'If no items selected array will be vbEmpty
Function ListboxSelectionArray(lisbox As ListBox, Optional columnindex As Integer = 1) As Variant
    With lisbox
        If .ItemsSelected.Count > 0 Then
            Dim str() As String: ReDim str(.ItemsSelected.Count - 1)
            Dim j As Integer
            For j = 0 To .ItemsSelected.Count - 1
                str(j) = CStr(.Column(columnindex - 1, .ItemsSelected(j)))
            Next
            ListboxSelectionArray = str
        Else
            ListboxSelectionArray = vbEmpty
        End If
    End With
End Function

应用程序库和编码中的一些数组构建器可以使看起来更 VB.NET