用c++编写Haskell解释器(使用ghc或hugs作为库)

我正在编写一个需要解释和评估haskell代码的c++应用程序。这段代码在编译时是未知的，而是由用户提供的。是否有一种方法可以使用haskell编译器/解释器(如GHCi或hugs)作为库?

我找到了FFI，但这似乎只适用于在编译时已知的haskell代码。
我找到了GHC API和提示，但它们似乎只在我想从haskell中解释haskell代码时才有效。

对于这种特殊的方法，我建议绑定到Hint，而不是使用GHC api，这只是对GHC api的简化包装。我之所以推荐它，是因为GHC api有一点陡峭的学习曲线。

但无论如何，就像我在我的评论中说的，这取决于你想要的深度，它需要很少的FFI调用。下面我给出一个例子，说明如何从加载的文件中运行表达式并返回结果(仅当有show实例时)。这只是基础，返回结果作为一个结构应该也是可能的。

module FFIInterpreter where
import Language.Haskell.Interpreter
import Data.IORef
import Foreign.StablePtr
type Session = Interpreter ()
type Context = StablePtr (IORef Session)
-- @@ Export
-- | Create a new empty Context to be used when calling any functions inside
--   this class.
--   .
--   String: The path to the module to load or the module name
createContext :: ModuleName -> IO Context
createContext name 
  = do let session = newModule name 
       _ <- runInterpreter session
       liftIO $ newStablePtr =<< newIORef session
newModule :: ModuleName -> Session
newModule name = loadModules [name] >> setTopLevelModules [name]
-- @@ Export
-- | free a context up
freeContext :: Context -> IO ()
freeContext = freeStablePtr
-- @@ Export = evalExpression
runExpr :: Context -> String -> IO String
runExpr env input
  = do env_value <- deRefStablePtr env
       tcs_value <- readIORef env_value
       result    <- runInterpreter (tcs_value >> eval input) 
       return $ either show id result

因为我们必须退出haskell land，我们必须有一些方法来引用上下文，我们可以用StablePtr来做到这一点，我只是把它包装在IORef中，以使它可变，以防你将来想要改变东西。请注意，GHC API不支持内存缓冲区的类型检查，所以你必须在加载之前将你想要解释的代码保存到一个临时文件中。

-- @@注释是为我的工具Hs2lib，不要介意他们，如果你不使用它。

我的测试文件是

module Test where
import Control.Monad
import Control.Monad.Instances
-- | This function calculates the value x->x*x
bar :: Int -> Int
bar = join (*)

我们可以用一个简单的test 来测试

*FFIInterpreter> session <- createContext "Test"
*FFIInterpreter> runExpr session "bar 5"
"25"

是的，它在Haskell中工作，现在让它在Haskell之外工作。

只需在文件的顶部添加一些Hs2lib关于如何封送ModuleName的指令，因为该类型是在没有源的文件中定义的。

{- @@ INSTANCE ModuleName 0                 @@ -}
{- @@ HS2HS ModuleName CWString             @@ -}
{- @@ IMPORT "Data.IORef"                   @@ -}
{- @@ IMPORT "Language.Haskell.Interpreter" @@ -}
{- @@ HS2C  ModuleName "wchar_t*@4"         @@ -}

或

{- @@ HS2C  ModuleName "wchar_t*@8"         @@ -}

如果在64位架构上，

和只调用Hs2lib

PS HaskellFFIInterpreter> hs2lib .FFIInterpreter.hs -n "HsInterpreter"
Linking main.exe ...
Done.

最后你会得到一个包含

的Include文件

#ifdef __cplusplus
extern "C" {
#endif
// Runtime control methods
// HsStart :: IO ()
extern CALLTYPE(void) HsStart ( void );
// HsEnd :: IO ()
extern CALLTYPE(void) HsEnd ( void );
// createContext :: ModuleName -> IO (StablePtr (IORef (Interpreter ())))
//
// Create a new empty Context to be used when calling any functionsinside this class.
// String: The path to the module to load or themodule name
//
extern CALLTYPE(void*) createContext (wchar_t* arg1);
// freeContext :: StablePtr (IORef (Interpreter ())) -> IO ()
//
// free a context up
//
extern CALLTYPE(void) freeContext (void* arg1);
// evalExpression :: StablePtr (IORef (Interpreter ())) -> String -> IO String
extern CALLTYPE(wchar_t*) evalExpression (void* arg1, wchar_t* arg2);
#ifdef __cplusplus
}
#endif

我还没有测试过c++端，但是没有理由它不应该工作。这是一个非常简单的例子，如果你把它编译成一个动态库，你可能需要重定向stdout, stderr和stdin。

由于GHC是用Haskell编写的，所以它的API只能从Haskell获得。正如Daniel Wagner建议的那样，在Haskell中编写所需的接口，并使用FFI将它们绑定到C中，这将是最简单的方法。这可能比使用GHC API到C的直接绑定更容易;你可以使用Haskell的优势来构建你需要的接口，并且只在顶层用c++与它们交互。

注意Haskell的FFI只会导出到C;如果你想要一个类似c++的包装器，你必须把它写成另一个层。

(顺便说一句，Hugs是古老且未维护的)

相关内容

最新更新

热门标签：