在 Groovy 系统脚本中更改作业参数值

Question

我的参数化自由式作业有一个字符串参数。 MAIL_PARAM默认值为 FREESTYLE_ERROR 。

我能够通过以下方式打印值：

println "MAIL_PARAM=$Mail_Param"  

在 Groovy 执行脚本中。现在我想根据一些条件更改此参数的值。但我无法改变它。我试过了：

MAIL_PARAM = 'String'
$MAIL_PARAM ='String'
${MAIL_PARAM} ='String'
def params = new StringParameterValue('MAIL_PARAM', 'String') 

还有一些，但没有一个有效。我必须更改它，因为根据我的 groovy 脚本的一些结果，我的参数内部需要不同的字符串。

在时髦的脚本之后，我需要将此参数传递给下一个作业。这工作正常。但我只得到默认值。

Answer 1

如果我理解正确，replaceAction 应该可以解决问题(还有 addOrReplaceAction(：

import hudson.model.ParametersAction
import hudson.model.ParameterValue
import hudson.model.StringParameterValue
def newMailParameter = new StringParameterValue('MAIL_PARAM', '...')
build.replaceAction(new ParametersAction(newMailParameter))

编辑：如果您收到错误"当前构建没有任何参数"，请尝试"build.addOrReplaceAction"代替"build.replaceAction"。

Answer 2

从 setBuildParameters： 修改： http://jenkins-ci.361315.n4.nabble.com/Modifying-a-builds-parameters-in-a-system-Groovy-script-td4636966.html

def addOrReplaceParamValue = { String name,String value ->
    def build = currentBuild.getRawBuild();
    def npl = new ArrayList<StringParameterValue>()
    def pv = new hudson.model.StringParameterValue(name,value);
    npl.add(pv);
    def newPa = null
    def oldPa = build.getAction(hudson.model.ParametersAction.class)
    if (oldPa != null) {
        build.actions.remove(oldPa)
        newPa = oldPa.createUpdated(npl)
    } else {
        newPa = new hudson.model.ParametersAction(npl)
    }
    build.actions.add(newPa);       
};  
addOrReplaceParamValue("P1","p1");

Answer 3

如果需要根据原始值进行修改，下面是一个更完整的示例：

import hudson.model.ParametersAction
import hudson.model.ParameterValue
import hudson.model.StringParameterValue
def transformJobParameter(Closure transform) {
    build.getActions(ParametersAction).each { paramAction ->
        List<ParameterValue> overrides = []
        paramAction.each { param ->
            // Transformation takes a ParameterValue object but returns only its new value object, if any.
            def newValue = transform(param)
            if (newValue != null && newValue != param.value) {
                // Create whatever the original object type was, but with a new value.
                def newParam = param.class.newInstance([param.name, newValue, param.description] as Object[])
                overrides << newParam
                println("INFO  - Transformed ${param.name} parameter from '${param.value}' to '$newValue'.")
            }
        }
        if (!overrides.empty) {
            def mergedParamAction = paramAction.merge(new ParametersAction(overrides))
            build.replaceAction(mergedParamAction)
        }
    }
}
transformJobParameter { param ->
    if (param instanceof StringParameterValue) {
        def value = param.value.trim()
        if (param.name == 'MAIL_PARAM') {
            'String'
        } else {
            value
        }
    }
}