模式匹配 Erlang 字符串作为函数中的列表

Question

我最近开始研究Erlang，遇到了一个我无法解释的奇怪异常。

我的源代码如下：

-module(balanced_brackets).                                                                                                              
-author("Irrelevant").
-compile(export_all).
is_balanced(String) -> is_balanced(String, 0, 0).
is_balanced([H | T], Opening, Closing) when H =:= "{" ->
    is_balanced(T, Opening + 1, Closing);
is_balanced([H | T], Opening, Closing) when H =:= "}" ->
    is_balanced(T, Opening, Closing + 1);
is_balanced([], Opening, Closing) -> (Opening - Closing).

非常基本的代码，用于计算字符串中右大括号和左大括号的数量。

在 Erlang shell 中，当我尝试调用函数时，is_balanced如下： balanced_brackets:is_balanced("{}").

输出以下错误：

** exception error: no function clause matching balanced_brackets:is_balanced("{}",0,0) (balanced_brackets.erl, line 7)

但是，如果我将参数作为显式列表传递，则模式匹配可以正常工作： balanced_brackets:is_balanced(["{", "}"]).

Erlang 字符串不是只是内部列表吗？为什么使用构造[H | T]模式匹配字符串不正确？

执行 BIF is_list("{}").返回true 。

我真诚地感谢有人对例外的解释。

谢谢。

Erlang/OTP 17 [erts-6.2] [source-aaaefb3] [64-bit] [smp:2:2] [async-threads:10] [hipe] [kernel-poll:false]

Answer 1

问题是你的守卫定义，你正在与[123] "{"进行比较，即一个列表，一个代表{的元素。

您的模式匹配是正确的，但您需要匹配123而不是"{"(当然}也是如此(。

修复代码(并保持其可读性(的最简单方法是与[H]进行比较，而不是在防护中H：

is_balanced([H | T], Opening, Closing) when [H] =:= "{" ->
    is_balanced(T, Opening + 1, Closing);

Answer 2

没有必要像本答案中建议的那样使用数字来表示字符。相反，只需使用 Erlang 字符常量。例如，要表示{字符，应使用 ${ .

修复代码的一个好方法是完全避免守卫，只匹配函数头中的${和$}字符，如下所示：

is_balanced([${ | T], Opening, Closing) ->
    is_balanced(T, Opening + 1, Closing);
is_balanced([$} | T], Opening, Closing) ->
    is_balanced(T, Opening, Closing + 1);

然后，您需要另一个子句来处理原始代码中缺少的 ${ 和 $} 以外的字符：

is_balanced([_ | T], Opening, Closing) ->
    is_balanced(T, Opening, Closing);

最后，保留原始的 final 子句来处理空列表，结束递归：

is_balanced([], Opening, Closing) -> (Opening - Closing).

还有一件事：给定函数名称 is_balanced ，它似乎想要返回一个布尔值。如果是这样，请将 top 函数更改为：

is_balanced(String) -> is_balanced(String, 0, 0) == 0.