如何使用 groovy 更新响应 xml 并打印它

Question

我对Groovy和SOAPUI完全陌生。

场景 ：比较两个 xml 响应。（两者都属于不同的项目）

尝试的方法：捕获响应并将响应写入文件，比较两个文件。

面临的问题：时间戳不匹配，因为两个请求在不同的时间运行

由于上述问题，我尝试获取时间戳的 Node 值并将其更改为两个响应的 *。但是我无法写入更改的响应值。

时髦的脚本：

def groovyUtils = new com.eviware.soapui.support.GroovyUtils( context ); 
log.info( groovyUtils.projectPath ); 
def holder = groovyUtils.getXmlHolder( "loginRequest#Response" ) 
holder.setNodeValue( "//ns3:loginUserResponse[1]/ns3:loginUserResponse/userModel/auditModel/timestamp", "1" ); 

最初def holder保存响应 xml，但在持有者中获取 xml 后，我正在更新节点值。我不知道如何进一步进行。我需要将更新的 xml 写入文件。

Answer 1

这是一个示例 groovy 脚本，它使用任意 xml 并根据特定条件更新元素值。然后，它会根据请求将更新的数据写回文件。请遵循脚本的内联注释。

我相信这将有助于您的理解，您将能够将其应用于您的实际 xml。

这个脚本实际上做了什么？
当汽车名称为 i30 时，此 xml 的madeBy值不正确。并且喜欢用Hyundai更新xml并将其写入指定的文件。

/**
* below is the groovy script which read and parses xml
* and updates its value and then writes back to file
**/
import groovy.xml.*
//Sample xml string
def xml = '''<?xml version="1.0" encoding="utf-8"?>
<cars>
  <car>
    <name>Jetta</name>
    <madeBy>Volkswagen</madeBy>
  </car>
  <car>
    <name>Polo GT</name>
    <madeBy>Volkswagen</madeBy>
  </car>
  <car>
    <name>i30</name>
    <madeBy>Typo</madeBy>
  </car>
</cars>'''
//if you want to pass the dynamic response instead of above fixed xml, then
//use below statements by uncommenting below one and replace value for TEST_STEP_NAME and
//comment above xml statement
/**
def xml = context.expand('${TEST_STEP_NAME#Response}')
**/
//parse the xml string and create object
def cars = new XmlSlurper().parseText(xml)
//find the car whose name is i30 and update its madeBy element value to Hyundai
cars.'**'.find { if (it.name == 'i30') it.madeBy = 'Hyundai'}
//print changed cars object
println XmlUtil.serialize(cars)
//Serializes and Writes cars object into given file
new File('c:/Temp/test1.xml').write(XmlUtil.serialize(cars))

如果打开 xml 文件，输出应如下所示：

<?xml version="1.0" encoding="UTF-8"?>
<cars>
  <car>
    <name>Jetta</name>
    <madeBy>Volkswagen</madeBy>
  </car>
  <car>
    <name>Polo GT</name>
    <madeBy>Volkswagen</madeBy>
  </car>
  <car>
    <name>i30</name>         
    <madeBy>Hyundai</madeBy>
  </car>
</cars>

您可能还会发现此示例很有用，它说明了如何完全创建新的 xml。