findall的替代方案

Question

我正试图在Prolog中创建findall的替代方案。

我拥有的是：

solutions(A,T,S) :- 
   T,
   assert(temp(A)),
   fail.
solutions(A,T,S) :-
   obtain([],S).
obtain(X,S) :-
   retract(temp(A)),
   obtain([A|X],S).
obtain(S,S).

然而，这给了我不一致的结果。怎么了？提前谢谢。

Answer 1

您的实现存在几个问题。

1. 一开始没有清理。在T, 之前添加retractall(temp(_))

2. obtain/2将以许多不同的答案成功，因为retract(temp(A))将给出许多答案，并且因为第二子句obtain(S,S)将始终是一个解决方案。这可以通过在retract之后添加剪切来保存

   ？-获得（[]，S）。S=[2,1]；S=[1]；S=[2]；S=[]；false。

3. 您可能希望通过使用asserta/1或重新定义obtain/2来更改顺序。

4. 你的定义不是重新进入。这是不可能轻易解决的。您可能需要一些类似gensym的功能，或者一些更高级的功能。

5. 有关assert/1与assertz/1的详细信息，请参见此答案。

Answer 2

试试这个，我们在retract/1和显式assertz/1:之后剪切（！）

solutions(A,T,_) :- 
   T,
   assertz(temp(A)),
   fail.
solutions(_,_,S) :-
   obtain(S).
obtain([A|S]) :-
   retract(temp(A)), !,
   obtain(S).
obtain([]).

工作正常，但不可重入，第二个查询结果错误：

?- solutions(X,between(1,3,X),L).
L = [1, 2, 3].
?- solutions(X-R,(between(1,3,X),solutions(Y,between(1,X,Y),R)),L).
L = [3-[2-[1-[1], 1, 2], 1, 2, 3]].

编辑08.11.2020：
以下是使用gensym/2:的可重入解决方案

solutions(A,T,L) :-
   setup_call_cleanup(
      gensym('bag',B),
      solutions(B,A,T,L),
      retractall(temp(B,_))).
solutions(B,A,T,_) :- 
   T,
   assertz(temp(B,A)),
   fail.
solutions(B,_,_,S) :-
   obtain(B,S).
obtain(B,[A|S]) :-
   retract(temp(B,A)), !,
   obtain(B,S).
obtain(_,[]).

现在两个查询都可以正常工作：

?- solutions(X,between(1,3,X),L).
L = [1, 2, 3].
?- solutions(X-R,(between(1,3,X),solutions(Y,between(1,X,Y),R)),L).
L = [1-[1], 2-[1, 2], 3-[1, 2, 3]].

警告：具有逻辑更新语义的Prolog系统
在重复收回/1的过程中可能效率低下。