在Rebol中删除序列中的重复对象

Question

在R2和R3中，我可以使用unique从系列中删除重复项：

>> a: [1 2 2 3]
>> length? a
== 4
>> length? unique a
== 3

如何对一系列对象执行相同的操作？例如

b: reduce [
    make object! [a: 1] 
    make object! [b: 2] 
    make object! [b: 2] 
    make object! [c: 3]
]
>> length? b
== 4
>> length? unique b
== 4  ; (I'd like it to be 3)

Answer 1

UNIQUE和其他集合操作中相等检查的实现似乎是Cmp_Value，进行比较的方法是减去对象的帧指针。如果减法为零（例如，这些是相同的对象），则比较被视为匹配：

f系列.cLine283，R3Alpha开源版

如果您查看周围的代码，您将在同一例程中看到对Cmp_Block的调用。在Cmp_Block的情况下，它进行递归比较，并尊重大小写敏感性。。。因此，块和对象的行为方式不同：

f系列.c 中的Cmp_Block（）

考虑到它是这样写的，如果你希望UNIQUE操作基于对象与其身份的逐字段比较，那么除了编写自己的例程并调用EQUAL？。。。或者修改C代码。

这里有一个不需要更改C源的简短破解，它对UNIQUE的输出执行MAP-EACH。身体过滤掉任何EQUAL？已经看到的对象（因为当MAP-EACH的主体返回未设置时，它不会向结果添加任何内容）：

my-unique: function [array [block!]] [
    objs: copy []
    map-each item unique array [
        if object? :item [
            foreach obj objs [
                if equal? item obj [unset 'item break]
            ]
            unless unset? :item [append objs item]
        ]
        :item ;-- if unset, map-each adds nothing to result
    ]
]

不幸的是，您必须使用BLOCK！而不是地图！以便在行进过程中跟踪对象，因为MAP！当前不允许对象作为键。如果他们允许的话，他们可能会遇到同样的问题，即不会对字段相等的对象进行相同的哈希处理。

（注意：修复这个问题和其他问题是Ren-C分支的关注点，Ren-C分支除了现在是最快的具有基本修复的Rebol解释器外，还对设置操作进行了一些增强。聊天中的讨论）

Answer 2

EQUAL？和SAME？仅当对象是相同的对象引用时，才会为对象返回true。我写了一个函数来检查对象之间的相似性，如果两个对象具有相同值和相同类型的相同单词，则返回true：

similar?: func [
    {Returns true if both object has same words in same types.}
    o [object!] p [object!] /local test
][
    test: [if not equal? type? get in o word type? get in p word [return false]]
    foreach word sort first o test
    foreach word sort first p test
    true
]

您可以按照以下方式进行测试：

>> o: make object! [b: 2]
>> p: make object! [b: 2]
>> equal? o p
== false
>> same? o p
== false
>> similar? o p
== true

你可以在你的情况下使用它。

Answer 3

unique+: func [array [block!]] [
    objs: copy []
    map-each item unique array [
        if object? :item [
            foreach obj objs [
                if equal-object? :item :obj [unset 'item break]
            ]
            if value? 'item [append objs item]
        ]
        ;-- If unset, map-each adds nothing to result under R3.
        ;   R2 behaves differently. This works for both.
        either value? 'item [:item] [()]
    ]
]
equal-object?: func [
    "Returns true if both objects have same words and values."
    o [object!] p [object!]
][
    if not equal? sort words-of o sort words-of p [return false]
    foreach word words-of o [
        if not equal? o/:word p/:word [return false]
    ]
    true
]