从终端控制台手动发送邮件

Question

我们有一个类，它构建并发送邮件消息。我想做一些更改，但在此之前，我想测试一些东西（比如URL的显示方式）。我正试图从控制台手动发送消息，但遇到了一些错误。这是类的SendMessage方法：

Method SendMessage(pSubject As %String, pMessage As %String, pEmailAddresses) As %Status
{
    set tSC=$$$OK
    set tMailMessage=##class(%Net.MailMessage).%New()
    do tMailMessage.To.Insert($PIECE(pEmailAddresses,",",1))
    for tI=2:1:$LENGTH(pEmailAddresses,",") {
        do tMailMessage.Cc.Insert($PIECE(pEmailAddresses,",",tI))
    }
    set tMailMessage.Subject=pSubject
    set tMailMessage.Charset="iso-8859-1"
    set tSC=tMailMessage.TextData.Write(pMessage)
    quit:'tSC
    Set tSC1=..Adapter.SendMail(tMailMessage)
    if 'tSC1 {
        //Log warning about being unable to send mail.
        do $SYSTEM.Status.DecomposeStatus(tSC1,.err)
        $$$LOGWARNING("Could not send email: "_err(err))
        kill err
    }
    quit tSC
}

从终端，我可以实例化MailMessage类并设置主体数据，但当我尝试发送时，我会收到一个错误：

USER>set tMailMessage=##class(%Net.MailMessage).%New()
USER>do tMailMessage.To.Insert("[e-mail]")
USER>set tSC=tMailMessage.TextData.Write("This is a URL test http://www.google.com, thank you")
USER>set tMailMessage.Subject="This is a test"
USER>set tMailMessage.Charset="iso-8859-1"
USER>set tSC1=..Adapter.SendMail(tMailMessage)
SET tSC1=..Adapter.SendMail(tMailMessage)
^
<NO CURRENT OBJECT>

正如你所看到的，当我尝试SendMail时，它告诉我NO CURRENT OBJECT

更新我注意到了班上最上面的几行字：

Parameter ADAPTER = "EnsLib.EMail.OutboundAdapter";
Property Adapter As EnsLib.EMail.OutboundAdapter;

所以我尝试了USER>set tSC1=EnsLib.EMail.OutboundAdapter.SendMail(tMailMessage)，但结果是<UNDEFINED> *EnsLib

Answer 1

我想你正在为Ensemble Service工作。但是对于测试，您不应该使用这些类。对于发送电子邮件，您可以直接使用%Net.SMTP。所以，与其。。Adapter.SendMail使用此代码

set s=##class(%Net.SMTP).%New()
set s.smtpserver="SMTP server name"
#; if SMTP server needs auth
set auth=##class(%Net.Authenticator).%New() ; use default authentication list
set auth.UserName="myUser"
set auth.Password="myPassword"
set s.authenticator=auth
set status=s.Send(tMailMessage)
if $$$ISERR(status) do $system.OBJ.DisplayError(status)