帮助或更新 Clojure 列表和惰性序列

Question

如果我有一个向量(def v [1 2 3])，我可以用(assoc v 0 666)替换第一个元素，得到[666 2 3]

但是，如果我在映射向量后尝试执行相同的操作：

(def v (map inc [1 2 3]))
(assoc v 0 666)

引发以下异常：

ClassCastException clojure.lang.LazySeq cannot be cast to clojure.lang.Associative

编辑或更新惰性序列的单个元素的最惯用方法是什么？

我应该使用map-indexed并仅更改索引 0 还是将惰性序列实现为向量，然后通过 assoc/update 对其进行编辑？ 第一个具有保持懒惰的优点，而第二个效率较低，但可能更明显。

我想对于第一个元素，我也可以使用下降和缺点。 还有其他方法吗？ 我在任何地方都找不到任何例子。

Answer 1

编辑或更新惰性序列的单个元素的最惯用方法是什么？

没有用于修改序列/列表的单个元素的内置函数，但map-indexed可能是最接近的。对于列表来说，这不是一个有效的操作。假设你不需要懒惰，我会将序列倒入一个向量中，这就是mapv所做的，即(into [] (map f coll)).根据您使用修改后的序列的方式，对其进行矢量化和修改可能同样有效。

您可以使用map-indexed编写一个函数来执行类似且懒惰的操作：

(defn assoc-seq [s i v]
(map-indexed (fn [j x] (if (= i j) v x)) s))

或者，如果您想在不矢量化的情况下懒惰地一次性完成这项工作，您也可以使用换能器：

(sequence
(comp
(map inc)
(map-indexed (fn [j x] (if (= 0 j) 666 x))))
[1 2 3])

意识到您的用例是仅修改惰性序列中的第一项，然后您可以在保持惰性的同时做一些更简单的事情：

(concat [666] (rest s))

更新回复：评论优化：当更新 1,000,000 个元素延迟序列中的第 500,000 个元素时，leetwinski 的assoc-at函数速度快 ~8ms，所以如果你想从本质上低效的操作中榨取每一点性能，你应该使用他的答案：

(def big-lazy (range 1e6))
(crit/bench
(last (assoc-at big-lazy 500000 666)))
Evaluation count : 1080 in 60 samples of 18 calls.
Execution time mean : 51.567317 ms
Execution time std-deviation : 4.947684 ms
Execution time lower quantile : 47.038877 ms ( 2.5%)
Execution time upper quantile : 65.604790 ms (97.5%)
Overhead used : 1.662189 ns
Found 6 outliers in 60 samples (10.0000 %)
low-severe     4 (6.6667 %)
low-mild   2 (3.3333 %)
Variance from outliers : 68.6139 % Variance is severely inflated by outliers
=> nil
(crit/bench
(last (assoc-seq big-lazy 500000 666)))
Evaluation count : 1140 in 60 samples of 19 calls.
Execution time mean : 59.553335 ms
Execution time std-deviation : 4.507430 ms
Execution time lower quantile : 54.450115 ms ( 2.5%)
Execution time upper quantile : 69.288104 ms (97.5%)
Overhead used : 1.662189 ns
Found 4 outliers in 60 samples (6.6667 %)
low-severe     4 (6.6667 %)
Variance from outliers : 56.7865 % Variance is severely inflated by outliers
=> nil

在大型惰性序列中更新第一项时，assoc-at版本的速度快 2-3 倍，但不比(last (concat [666] (rest big-lazy)))快。

Answer 2

如果真的需要此功能(我强烈怀疑)，我可能会使用这样的通用功能：

(defn assoc-at [data i item]
(if (associative? data)
(assoc data i item)
(if-not (neg? i)
(letfn [(assoc-lazy [i data]
(cond (zero? i) (cons item (rest data))
(empty? data) data
:else (lazy-seq (cons (first data)
(assoc-lazy (dec i) (rest data))))))]
(assoc-lazy i data))
data)))
user> (assoc-at {:a 10} :b 20)
;; {:a 10, :b 20}
user> (assoc-at [1 2 3 4] 3 101)
;; [1 2 3 101]
user> (assoc-at (map inc [1 2 3 4]) 2 123)
;; (2 3 123 5)

另一种方法是使用split-at：

(defn assoc-at [data i item]
(if (neg? i)
data
(let [[l r] (split-at i data)]
(if (seq r)
(concat l [item] (rest r))
data))))

请注意，这两个函数都会短路 coll 遍历，而映射方法不会。这里有一些快速而肮脏的基准：

(defn massoc-at [data i item]
(if (neg? i)
data
(map-indexed (fn [j x] (if (== i j) item x)) data)))
(time (last (assoc-at (range 10000000) 0 1000)))
;;=> "Elapsed time: 747.921032 msecs"
9999999
(time (last (massoc-at (range 10000000) 0 1000)))
;;=> "Elapsed time: 1525.446511 msecs"
9999999