Raku:一行表达式从字符串中捕获组?

Question

我从字符串中捕获一个数字：

my $n1;
if $string1 ~~ /(<[0..4]>)$/ {
    $n1 = $0;
} else {
    put "$string1 failed regex.";
    die;
}

这是很多行，但我可以在一行中复制和编辑字符串，因此：

my $string2 = $group2.subst(/<[0..4]>$/, '');

我还在学习 raku/perl6，我已经浏览了 https://docs.perl6.org/type/Str，看起来 Raku 不能做到这一点......但我不确定。

有没有办法在一行中捕获子字符串，类似于上面的第一个代码示例？

我在脚本中反复执行此过程，它确实会缩短我的脚本

Answer 1

可以使用解构绑定将匹配的部分提取到变量中。对于给出的示例，我们可以像这样提取匹配的部分：

my ($n) := "abc123" ~~ /(<[1..4]>+)$/;
say $n;  # ｢123｣

这将扩展到提取匹配的多个部分：

my ($s, $n) := "abc123" ~~ /(<[a..z]>+)(<[1..4]>+)$/;
say $s;  # ｢abc｣
say $n;  # ｢123｣

Raku 中捕获的东西本身就是Match对象，但也可以在解构中使用强制，以便将其转换为整数：

my (Int() $n) := "abc123" ~~ /(<[1..4]>+)$/;
say $n;       # 123
say $n.WHAT;  # (Int)

它甚至可以与命名匹配项一起使用(这里有点人为，但如果您进行子规则调用，则很方便(：

my (:$s, :$n) := "abc123" ~~ /$<s>=(<[a..z]>+) $<n>=(<[1..4]>+)$/;
say $s;  # ｢abc｣
say $n;  # ｢123｣

这样做的明显缺点是，如果不匹配，可能会得到异常。然而，值得庆幸的是，这可以与if相结合：

if "abc123" ~~ /(<[a..z]>+)(<[1..4]>+)$/ -> ($s, $n) {
    say $s;
    say $n;
}

同样的语法也有效，因为解构绑定实际上只是签名的应用。

Answer 2

也许.match就是你要找的。

my $string1='4';
my $n2 = $string1.match(/(<[0..4]>)$/) // die 'error';
say $n2.values;