使用 SSE(IA32 程序集)执行简单的算术运算

Question

在我的大学里，我们刚刚接触到IA32 SSE。我正在尝试做的是添加两个向量（他们称之为"打包值"，这意味着该向量包含四个 32 位单精度浮点数。一个 verctor 的大小为 128 位。这是我正在尝试做的：

%xmm0      | 5.5 | 1.2 | 2.4 | 7.0 |
%xmm1      | 3.0 | 1.5 | 3.5 | 2.2 |
              |     |     |     |
              +     +     +     +
              |     |     |     |
              V     V     V     V
%xmm0      | 8.5 | 2.7 | 5.9 | 9.2 |

但是，在幻灯片上，它们仅显示以下代码片段，我根本无法开始工作：

# %eax and %ebx contain the addresses of the two vectors that are to be added
movups (%eax), %xmm0
movups (%ebx), %xmm1
addps %xmm1, %xmm0
movups %xmm0, result

这就提出了两个问题：

1. 我如何首先创建这些向量以及如何使 %eax 和 %ebx 指向它们？

2. 如何打印结果以检查操作是否成功？

这是我尝试过的。下面的代码编译，当我运行它时不会崩溃。但是，根本没有输出... ：/

.data
    x0: .float 7.0
    x1: .float 2.4
    x2: .float 1.2
    x3: .float 5.5
    y0: .float 2.2
    y1: .float 3.5
    y2: .float 1.5
    y3: .float 3.0
    result: .float 0
    intout: .string "Result: %f.n"
.text
.global main
main:
    pushl x3
    pushl x2
    pushl x1
    pushl x0
    movl %esp, %eax
    pushl y3
    pushl y2
    pushl y1
    pushl y0
    movl %esp, %ebx
    movups (%eax), %xmm0
    movups (%ebx), %xmm1
    addps %xmm1, %xmm0
    movups %xmm0, result
    pushl result
    pushl $intout
    call printf
    addl $40, %esp
    movl $1, %eax
    int $0x80

Answer 1

printf的%f说明符表示双精度参数，而不是浮点参数。因此，您需要在结果向量中隐藏单浮点数并将它们移动到堆栈中。这就是我会这样做的方式：

.section ".rodata"
fmt:    .string "%f %f %f %fn"
        .align 16
vec1:
        .float 7.0
        .float 2.4
        .float 1.2
        .float 5.5
vec2:
        .float 2.2
        .float 3.5
        .float 1.5
        .float 3.0    
.data
        .align 16
result:
        .float 0.0
        .float 0.0
        .float 0.0
        .float 0.0
        .text
.globl main
main:
        movl    %esp, %ebp
        andl    $-16, %esp      # align stack
        movaps  vec1, %xmm0
        movaps  vec2, %xmm1
        addps   %xmm1, %xmm0
        movaps  %xmm0, result
        subl    $36, %esp
        movl    $fmt, (%esp)
        movss   result, %xmm0
        cvtss2sd %xmm0, %xmm0
        movsd   %xmm0, 4(%esp)
        movss   result+4, %xmm0
        cvtss2sd %xmm0, %xmm0
        movsd   %xmm0, 12(%esp)
        movss   result+8, %xmm0
        cvtss2sd %xmm0, %xmm0
        movsd   %xmm0, 20(%esp)
        movss   result+12, %xmm0
        cvtss2sd %xmm0, %xmm0
        movsd   %xmm0, 28(%esp)
        call    printf
        addl    $36, %esp
        xorl    %eax, %eax
        movl    %ebp, %esp
        ret

Answer 2

您似乎对如何在多个数据项上声明标签以及如何将标签加载到寄存器中感到困惑。 标签只是一个地址 - 内存中的一个点 - 没有任何大小或与之相关的任何其他内容。 标签后面的内容位于内存中的连续地址中。 因此，您将引用向量的标签声明为：

x:
    .float 7.0
    .float 2.4
    .float 1.2
    .float 5.5

现在，您可以通过简单的移动将该地址加载到寄存器中，然后使用寄存器加载向量：

    movl   $x, %eax
    movups (%eax), %xmm0

或者，您可以直接从标签加载

    movups x, %xmm0