在 XSLT 中创建映射

Question

<xsl:variable name="map">
   <map>
        <item key="Name" value="John"/>
        <item key="Address" value="Un_Known"/>
        <item key="Phone" value="(878)876678"/>
        <item key="Last Name" value="Verner"/>
    </map>
</xsl:variable>
<xsl:for-each select "$map/map/item">
   <xsl:if test="./@key = $input">
      <!-- cool user is asking for something know .. do something fancy -->
   </xsl:if>
<xsl:for-each>

我想在我的 XSLT 中声明一个类似映射的结构，然后想要访问它。显然，我不想使用额外的命名空间，因此使用 exsl：node-set 不是我现在正在寻找的解决方案。

我正在使用 XSLT 1.0 撒克逊语。

有没有更好的方法来做我想做的事情？

谢谢卡雷普尔

---

下面提到的所有答案都是正确有效的。我们最终决定使用"exsl：node-set">

感谢您的建议..

Answer 1

如果您使用的是 Saxon，那么很难理解为什么您仍在使用 XSLT 1.0。这种事情(以及许多其他事情(在 XSLT 2.0 中要容易得多 - 是时候向前迈进了。

Answer 2

可以直接在 XSLT 中包含额外的 XML 信息，如<map>。该 XML 数据需要绑定到命名空间(XSLT 命名空间除外(，但它可以是任何命名空间。

可以使用带有空字符串的 document() 函数来访问 XSLT 中的数据，该函数将加载 XSLT 文档。

顺便提一下，您可以通过在xsl:for-each选择的 XPath 上使用谓词筛选器来消除对<xsl:if>的需求。

例如：

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
    version="1.0"
    xmlns:my="http://stackoverflow.com/questions/12146687/creating-a-map-in-xlst">
    <xsl:param name="input" />
    <my:map >
        <item key="Name" value="John"/>
        <item key="Address" value="Un_Known"/>
        <item key="Phone" value="(878)876678"/>
        <item key="Last Name" value="Verner"/>
    </my:map>
    <xsl:template match="/">
        <xsl:for-each select="document('')/*/my:map/item[@key=$input]">
                <!-- cool user is asking for something know .. do something fancy -->
        </xsl:for-each>
    </xsl:template>
</xsl:stylesheet>

Answer 3

如果您不想使用 node-set() 扩展功能，您可以将<map>数据放在单独的 XML 文件中，例如 map.xml .然后使用 document('map.xml') 从样式表中访问该文件。然后，您可以使用 XPath 表达式访问地图的内容，如上所示。

Answer 4

你得到了三个非常好的答案。

下面是另一个，它演示了如何使用键来访问查找表(实际上，查找表将驻留在单独的 XML 文档中(：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:my="my:my" exclude-result-prefixes="my">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:param name="pInput" select="'Phone'"/>
   <my:map>
        <item key="Name" value="John"/>
        <item key="Address" value="Un_Known"/>
        <item key="Phone" value="(878)876678"/>
        <item key="Last Name" value="Verner"/>
    </my:map>
 <xsl:key name="kLookup" match="item/@value" use="../@key"/>
 <xsl:template match="/">
     <xsl:for-each select="document('')">
       <xsl:value-of select="key('kLookup', $pInput)"/>
     </xsl:for-each>
 </xsl:template>
</xsl:stylesheet>

将此转换应用于任何 XML 文档(未使用(时，将生成所需的正确结果：

(878)876678

---

在 XSLT 2.0 中，不需要xsl:for-each，因为 key() 函数接受指定要编制索引的文档的第三个参数：

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:my="my:my" exclude-result-prefixes="my">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:param name="pInput" select="'Phone'"/>
   <my:map>
        <item key="Name" value="John"/>
        <item key="Address" value="Un_Known"/>
        <item key="Phone" value="(878)876678"/>
        <item key="Last Name" value="Verner"/>
    </my:map>
 <xsl:key name="kLookup" match="item/@value" use="../@key"/>
 <xsl:template match="/">
       <xsl:value-of select="key('kLookup', $pInput, document(''))"/>
 </xsl:template>
</xsl:stylesheet>