从Ada程序启动可执行文件并读取结果

Question

我发现了这个问题，第一个答案包含一些示例代码，演示如何使用 Ada 代码启动可执行文件。可执行文件的输出将写入标准输出。

我有哪些选项可以读取可执行文件的输出以便在 Ada 中进行进一步解析/处理(例如逐行(？

Answer 1

如果您使用 GNAT，那么您可能需要查看GNAT.Expect包中的Get_Command_Output。下面是一个示例：

with Ada.Text_IO, GNAT.Expect;
procedure Main is
   Command    : constant String := "gnat";   
   Argument_1 : aliased String  := "--version";
   Input      : constant String := ""; 
   Status     : aliased Integer := 0;      
   --  Execute the command and retrieve the output.
   Output : String :=
              GNAT.Expect.Get_Command_Output
                (Command    => Command,
                 Arguments  => (1 => Argument_1'Unchecked_Access),
                 Input      => Input,
                 Status     => Status'Access,
                 Err_To_Out => False);
   --  NOTE: Cheating with Unchecked_Access, OK for demo. You may want
   --        to properly new and Free these strings (see Argument_List 
   --        type in package GNAT.OS_Lib).
begin  
   Ada.Text_IO.Put_Line (Output);
end Main;

程序在执行后返回：

$ ./main
GNAT Community 2019 (20190517-83)
Copyright (C) 1996-2019, Free Software Foundation, Inc.
This is free software; see the source for copying conditions.
There is NO warranty; not even for MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.

可以看出，结果以单个字符串的形式返回。你将不得不自己做线分裂。

---

更新

针对

以下一些评论的更新。

如果您的目标是Windows平台，也可以考虑使用system功能(另请参阅SO上的这篇文章(。引用函数参考：

system 函数将命令传递给命令解释器，后者将字符串作为操作系统命令执行。

这类似于程序cmd.exe的功能。您可以通过将其输出重定向到文件(即使用 > (来获取命令的输出，然后读回它。下面是一个示例：

with Ada.Text_IO;              
with Ada.Text_IO.Unbounded_IO;
with Ada.Strings.Unbounded;
with Interfaces.C;
with Interfaces.C.Strings;         
procedure Main is
   use Ada.Strings.Unbounded;
   Content : Unbounded_String := Null_Unbounded_String;   
begin
   --  Execute.
   declare   
      use Interfaces.C;
      use Interfaces.C.Strings; 
      function system (command : chars_ptr) return int
        with Import, Convention => C, External_Name => "system";      
      command : chars_ptr := New_String("gnat --version > gnat_version.out");
      result  : int       := system (command); 
   begin
      --  Check value of result (omitted in this example).
      Free(Command);
   end;
   --  Read.
   declare
      use Ada.Text_IO;
      use Ada.Text_IO.Unbounded_IO;  
      Fd : File_Type;
   begin  
      Open (Fd, In_File, "./gnat_version.out");
      while not End_Of_File (Fd) loop
         Content := Content 
           & Unbounded_String'(Get_Line (Fd))
           & ASCII.CR & ASCII.LF;   --  Restore the line break removed by Get_Line.
      end loop;
      Close (fd);
   end;
   --  Show.
   Ada.Text_IO.Unbounded_IO.Put (Content);   
end Main;