确定TLabel的宽度

Question

Hello Stack Overflow Users

我有一个TGroupBox和一个TLabel。有了这个TLabel，我想显示候选人的姓氏和名字。有些候选人有不止一个名字，有时是三个，当这种情况发生时，TLabel并不总是适合我的TGroupBox。当这种情况发生时，我只显示姓和名，其余的只显示首字母。

为了做到这一点，我需要知道TLabel是否适合，如果值被分配给它。换句话说，在实际将值分配给Caption属性之前，我需要确定TLabel的宽度是多少，因为这将是显示变量数据的糟糕编程。

有什么建议吗?

Answer 1

我发现了一个非常简单的方法来做到这一点。基本上，您只想知道字符串的宽度(以像素为单位)，因此实现此目的的最佳方法是动态创建具有Font和Canvas属性的对象。我认为TBitmap将是最好的选择。下面是我使用的代码:

var
  sString: string;
  bmWidth: TBitmap;
  iWidth: Integer;
begin
  sString := edtEdit.Text;
  bmWidth := TBitmap.Create;
  try
    bmWidth.Canvas.Font.Assign(lblLabel.Font);
    iWidth := bmWidth.Canvas.TextWidth(sString);
  finally
    bmWidth.Free;
  end;
end;

Answer 2

在VCL中，TLabel使用Win32 API DrawText()函数计算文本宽度，使用GetDC()获得屏幕的HDC，然后SelectObject()将其当前Font选择到该HDC中。您必须在自己的代码中做同样的事情，例如:

// set Label1.AutoSize to False and Label1.Width to
// the max width your UI will accept the Label1 to be...
function WillFitInLabel(Label: TLabel; const S: String): Boolean;
var
  R: TRect;
  C: TCanvas;
  DC: HDC;
begin
  R := Rect(0, 0, Label.Width, 0);
  C := TCanvas.Create;
  try
    DC := GetDC(0);
    try
      C.Handle := DC;
      try
        C.Font := Label1.Font;
        Windows.DrawText(DC, PChar(S), Length(S), R, DT_SINGLELINE or DT_CALCRECT);
      finally
        C.Handle := 0;
      end;
    finally
      ReleaseDC(0, DC);
    end;
  finally
    C.Free;
  end;
  Result := (R.Width <= Label.Width);
end;
var
  Names: String;
begin
  Names := ...;
  if WillFitInLabel(Label1, Names) then
    Label1.Caption := Names
  else
    ...
end;

Answer 3

如果你想在多行中换行长文本，那么你可以使用标签的WordWrap := True和AutoSize := True属性。