名单列表哈斯克尔

Question

我有一个简单的问题，我是Haskell的新手，并试图学习很多东西。例如，我如何连接

 [( (0,1) , [1,2,3]) , ((1,2) , [7,8,9]) ,((0,1) , [4,5,6]) ] to [[1,2,3,4,5,6] , [7,8,9]]

我想连接对的第一个元素相等的列表。我试过了

 map concat list 
 map (t -> (filter (==).first) list ) list 

但是第一个不起作用，第二个给出错误。有什么想法吗？

Answer 1

使用Data.List中的几个函数，Data.Function.on变成：

import Data.List     (sortBy, groupBy)
import Data.Function (on)
sortByFirst :: Ord a => [(a, b)] -> [(a, b)]
sortByFirst = sortBy (compare `on` fst)

groupBy函数期望数据被排序，因此我们必须首先按每个内部元组排序(即按(a, b)排序 ((a, b), [x,y,z])

groupByFirst :: Eq a => [(a, b)] -> [[(a, b)]]
groupByFirst = groupBy ((==) `on` fst)

然后我们使用 groupBy 将生成的元组列表分组为元组列表列表，其中每个内部列表共享相同的第一个元素。

squishByFirst :: (Eq a, Ord a) => [(a, b)] -> [[b]]
squishByFirst = (map . concatMap) snd . groupByFirst . sortByFirst

然后，我们在snd上使用一些花哨的映射来滚动到每个内部列表中，拉出第二个元素(列表(，将它们组合在一起，然后返回结果。这相当于：

squishByFirst xs =
  let grouped = groupByFirst . sortByFirst $ xs
  in  [concat [ys | (_, ys) <- g] | g <- grouped]

---

您也可以将其实现为折叠Map.insertWith

import Data.Map (elems, empty, insertWith)
squishByFirst :: Ord k => [(k, [v])] -> [[v]]
squishByFirst = elems . mkMap
  where
  mkMap = foldr (uncurry (insertWith (++))) empty

或任何单体：

squishByFirst :: (Ord k, Monoid vs) => [(k, vs)] -> [vs]
squishByFirst = elems . mkMap
  where
  mkMap = foldr (uncurry (insertWith mappend)) empty