我正在使用Oracle SQL developer 2.1来创建同义词。
CREATE OR REPLACE SYNONYM "ETKS_PR_RW"."SQ_CLDOS_ATCHMNT_ID"
FOR "CLDOS_ONLINE_DBA"."SQ_CLDOS_ATCHMNT_ID";
我如何检查此同义词是否已存在,如果存在,则不要创建同义词。
当您使用 replace
关键字时,无需先检查同义词是否存在。您将覆盖以前名称存在的任何同义词。
使用 replace
的唯一原因是,您可能具有具有相同名称的不同同义词。如果您的数据库组织良好,则不应发生这种情况。您应该始终知道所有对象是什么以及同义词指向何处。
但是,如果您确实想要,有几个选项:
- 删除
replace
。如果同义词已存在并且不会被覆盖,则该语句将引发错误。 查询数据字典,因为您在多个架构中
all_synonyms
似乎是最好的选择。select * from all_synonyms where owner = 'ETKS_PR_RW' and synonym_name = 'SQ_CLDOS_ATCHMNT_ID';
如果你想将它们组合成一个块,那么你可以做这样的事情:
declare
l_exists number;
begin
-- check whether the synonym exists
select 1
into l_exists
from all_synonyms
where owner = 'ETKS_PR_RW'
and synonym_name = 'SQ_CLDOS_ATCHMNT_ID';
-- an error gets raise if it doesn-t.
exception when no_data_found then
-- DDL has to be done inside execute immediate in a block.
execute immediate 'CREATE OR REPLACE SYNONYM ETKS_PR_RW.SQ_CLDOS_ATCHMNT_ID
FOR CLDOS_ONLINE_DBA.SQ_CLDOS_ATCHMNT_ID';
end;
/
在稍微分开的请不要引用您的对象名称。Oracle 可以有大小写对象,但它非常非常不值得麻烦。所有对象将自动大写,因此您不需要"
。
我认为如果您删除了 OR REPLACE 关键字,它会提示您它存在
或者您可以使用这些表创建 pl/sql 代码
desc dba_synonyms
desc user_synonyms
使其更加灵活和定制
假设Oracle PL/SQL
DECLARE
src_schema VARCHAR2(256) := 'EMPIK_DYNAMO_01';
target_schema VARCHAR2(256) := 'EMPIK_PORTAL_BETA_1';
CURSOR src_objects IS
SELECT table_name AS object_name
FROM all_all_tables
WHERE owner = src_schema
UNION
SELECT sequence_name AS object_name
FROM all_sequences
WHERE sequence_owner = src_schema;
BEGIN
FOR next_row IN src_objects LOOP
BEGIN
EXECUTE IMMEDIATE 'CREATE or REPLACE SYNONYM '|| target_schema|| '.'
||
next_row.object_name|| ' for '|| src_schema|| '.'||
next_row.object_name;
EXCEPTION
WHEN OTHERS THEN
dbms_output.Put_line('ERROR WHILE CREATING SYNONYM FOR: '
|| next_row.object_name);
dbms_output.Put_line(SQLERRM);
END;
END LOOP;
END;
/
这里是针对您问题的定制
BEGIN
EXECUTE IMMEDIATE 'CREATE or REPLACE SYNONYM ETKS_PR_RW.SQ_CLDOS_ATCHMNT_ID FOR CLDOS_ONLINE_DBA.SQ_CLDOS_ATCHMNT_ID';
EXCEPTION
WHEN OTHERS THEN
dbms_output.Put_line ('ERROR WHILE CREATING SYNONYM FOR: SQ_CLDOS_ATCHMNT_ID');
dbms_output.Put_line (SQLERRM);
END;