如何使用XSLT为XML文件创建不同大小的页面

Question

我有一个这样格式的大XML文件:

<data jsxid="jsxroot" caseNumber="59878">
<record jsxid="1" poNumber="13-192208" manu="Biotronik" catNumber="101"  total="0" />
<record jsxid="2" poNumber="13-192208" manu="Biotronik" catNumber="102"  total="0" />               
<record jsxid="3" poNumber="13-192208" manu="Biotronik Total"  catNumber=""  total="1" />
<record jsxid="4" poNumber="13-192211" manu="Biotronik"  catNumber="103" total="0" />
<record jsxid="5" poNumber="13-192211" manu="Biotronik Total"  catNumber="" total="1"/>

我想把它分成25个或更少的一组，每一页必须以总行结束(@total="1")。

我使用下面的XSL插入了一个静态页码，但有时会在ponnumber组的中间断开，所以总数在下一页:

<xsl:output omit-xml-declaration="yes" indent="yes"/>
<xsl:param name="pagesize" select="25" />
<xsl:template match="data">
    <data>
        <xsl:for-each select="@*">                                    
            <xsl:copy-of select="." />                      
        </xsl:for-each>
        <xsl:apply-templates mode="page" select="record[position() mod $pagesize = 1]" />
    </data>
</xsl:template>
<xsl:template match="record" mode="page">
    <record jsxid="{position()}" >
        <xsl:apply-templates select=". | following-sibling::record[position() &lt; $pagesize]" />
    </record>       
</xsl:template>
<xsl:template match="record">
     <xsl:copy-of select="." />  
</xsl:template>

关于如何确保每页上的最后记录是总数，有什么想法吗?

编辑:我只是想澄清我用我发布的样式表做了什么。它为每条($pagesize)记录插入一个页面占位符(jsid = n)。因此，如果pagesize = 5的数据集类似于我发布的，输出是:

<data jsxid="jsxroot" caseNumber="59878">
<record jsxid="1">
<record jsxid="1" poNumber="13-192208" manufacturer="Biotronik" catalogNumber="101"      total="0" />
<record jsxid="2" poNumber="13-192208" manufacturer="Biotronik" catalogNumber="102"  total="0" />
<record jsxid="3" poNumber="13-192208" manufacturer="Biotronik Total"  catalogNumber=""  total="1" />
<record jsxid="4" poNumber="13-192211" manufacturer="Biotronik"  catalogNumber="103" total="0" />
<record jsxid="5" poNumber="13-192211" manufacturer="Biotronik Total"  catalogNumber="" total="1"/>
<record jsxid="2">  
<record jsxid="6" poNumber="13-192208" manufacturer="Biotronik" catalogNumber="101"  total="0" />
<record jsxid="7" poNumber="13-192208" manufacturer="Biotronik" catalogNumber="102"  total="0" />

我在通用接口的矩阵中显示此数据，并使用jsid在"页面"之间进行迭代。"

谢谢。

Answer 1

我用下面的代码插入了一个静态页码XSL

我在你发布的样式表中没有看到任何地方。假设分页是指为每个记录分配页码，请尝试:

XSLT 1.0

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:param name="pagesize" select="25" />
<xsl:key name="record" match="record" use="@poNumber" />
<xsl:template match="/data">
    <xsl:copy>
        <xsl:copy-of select="@*" />  
            <xsl:call-template name="paginate">
                <xsl:with-param name="orders" select="record[@total=1]"/>
                <xsl:with-param name="page" select="1"/>
                <xsl:with-param name="existing-lines" select="0"/>
        </xsl:call-template>    
    </xsl:copy>
</xsl:template>
<xsl:template name="paginate">
    <xsl:param name="orders" />
    <xsl:param name="page"/>
    <xsl:param name="existing-lines"/>
    <xsl:param name="current-order-records" select="key('record', $orders[1]/@poNumber)"/>
    <xsl:param name="added-lines" select="count($current-order-records)"/>
    <xsl:choose>
        <xsl:when test="$existing-lines + $added-lines > $pagesize">
            <xsl:call-template name="paginate">
                <xsl:with-param name="orders" select="$orders"/>
                <xsl:with-param name="page" select="$page + 1"/>
                <xsl:with-param name="existing-lines" select="0"/>
            </xsl:call-template>
        </xsl:when>
        <xsl:otherwise>
            <xsl:for-each select="$current-order-records">
                <record page="{$page}">
                    <xsl:copy-of select="@*"/>  
                </record>
            </xsl:for-each>
            <xsl:if test="count($orders) > 1">
                <xsl:call-template name="paginate">
                    <xsl:with-param name="orders" select="$orders[position() > 1]"/>
                    <xsl:with-param name="page" select="$page"/>
                    <xsl:with-param name="existing-lines" select="$existing-lines + $added-lines "/>
                </xsl:call-template>
            </xsl:if>
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>
</xsl:stylesheet>

你的输入太小，无法测试这个，所以…请注意，如果任何number有超过25条记录，这个程序将崩溃。

---

编辑:

为每个页面创建容器元素要困难得多:需要进行预处理。试一试:

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:exsl="http://exslt.org/common"
extension-element-prefixes="exsl">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:param name="pagesize" select="25" />
<xsl:key name="record" match="record" use="@poNumber" />
<xsl:variable name="root" select="/" />
<xsl:template match="/data">
    <!-- first-pass -->
    <xsl:variable name="index">
        <xsl:call-template name="paginate">
            <xsl:with-param name="orders" select="record[@total=1]"/>
            <xsl:with-param name="page" select="1"/>
            <xsl:with-param name="existing-lines" select="0"/>
        </xsl:call-template>    
    </xsl:variable>
    <xsl:variable name="index-entry" select="exsl:node-set($index)/entry" />
    <!-- output -->
    <xsl:copy>
        <xsl:copy-of select="@*" />  
        <xsl:for-each select="$index-entry[@page-start='true']">
            <record jsxid="{@page}">
                <xsl:variable name="poNumbers" select="$index-entry[@page=current()/@page]/@poNumber" />
                <xsl:for-each select="$root">
                    <xsl:copy-of select="key('record', $poNumbers)"/>
                </xsl:for-each>
            </record>
        </xsl:for-each>
    </xsl:copy>
</xsl:template>
<xsl:template name="paginate">
    <xsl:param name="orders" />
    <xsl:param name="page"/>
    <xsl:param name="existing-lines"/>
    <xsl:param name="current-order-records" select="key('record', $orders[1]/@poNumber)"/>
    <xsl:param name="added-lines" select="count($current-order-records)"/>
    <xsl:choose>
        <xsl:when test="$existing-lines + $added-lines > $pagesize">
            <xsl:call-template name="paginate">
                <xsl:with-param name="orders" select="$orders"/>
                <xsl:with-param name="page" select="$page + 1"/>
                <xsl:with-param name="existing-lines" select="0"/>
            </xsl:call-template>
        </xsl:when>
        <xsl:otherwise>
            <entry page="{$page}" page-start="{$existing-lines = 0}">
                <xsl:copy-of select="$orders[1]/@*"/> 
            </entry>
            <xsl:if test="count($orders) > 1">
                <xsl:call-template name="paginate">
                    <xsl:with-param name="orders" select="$orders[position() > 1]"/>
                    <xsl:with-param name="page" select="$page"/>
                    <xsl:with-param name="existing-lines" select="$existing-lines + $added-lines "/>
                </xsl:call-template>
            </xsl:if>
        </xsl:otherwise>
     </xsl:choose>
</xsl:template>
</xsl:stylesheet>

---

编辑2:

要计算最大PO所需的最小页面大小，请将此添加到样式表的顶层(在任何模板之外):

<xsl:variable name="largestPO">
    <xsl:for-each select="/data/record[@total = 1]">
        <xsl:sort select="count(key('record', @poNumber))" data-type="number" order="descending"/>
        <xsl:if test="position()=1">
            <xsl:value-of select="count(key('record', @poNumber))" />  
        </xsl:if>
    </xsl:for-each>
</xsl:variable>

现在您只需要将其与默认页面大小进行比较，并选择两者中较大的