我正在尝试通过批处理文件在Windows 2012上备份我的MySql数据库。
这是我所拥有的:
%mysql% -u %USER% -p%PASSWORD% -B -s -e"show databases" > %backupdir%mysqldblist.tmp
FOR /F %%D IN (%backupdir%mysqldblist.tmp) DO (
set DONTBACKUP=NOTHING
ECHO Creating backup for database ''%%D''
if [%%D]==[information_schema] set DONTBACKUP=TRUE
if [%%D]==[mysql] set DONTBACKUP=TRUE
if [%%D]==[performance_schema] set DONTBACKUP=TRUE
if [%%D]==[test] set DONTBACKUP=TRUE
PAUSE
IF [%DONTBACKUP%]==[TRUE] %mysqldump% -u %USER% -p%PASSWORD% --result-file="%backupdir%%%D_%mydate%.sql" "%%D"
PAUSE
)
我正在尝试排除 mysql、performance_schema 和测试等数据库,但它在第一次迭代后退出。我想我只是设置一个变量并检查它是否是某个数据库,但它只是没有发生,首先检查它退出。
有人可以指出我在这里做错了什么吗?
附加信息
这是我在命令提示符窗口中看到的,如果它有帮助的话:
ECHO Creating backup for database '%D'
if [%D] == [information_schema] set DONTBACKUP=TRUE
if [%D] == [mysql] set DONTBACKUP=TRUE
if [%D] == [performance_schema] set DONTBACKUP=TRUE
if [%D] == [test] set DONTBACKUP=TRUE
PAUSE
IF [] == [TRUE] "C:Program FilesMySQLMySQL Server 5.5binmysqldump"...
我看到有些不对劲,我现在正在尝试调试它,但我没有立即看到它。我不确定为什么%%D或为什么没有填充DONTBACKUP...
附加信息 #2
这就是我认为我失败的地方:
if [information_schema] == [information_schema] set DONTBACKUP=TRUE
它未设置为 TRUE,因此它会尝试执行备份。我不确定我忽略了什么,但为什么这种比较会失败?
在文件的开头添加以下行:
setlocal enabledelayedexpansion
在 for 循环中,当查看 DONTBACKUP
的值时,使用 !DONTBACKUP!
。此外,按照逻辑,DONTBACKUP
检查应该颠倒。
所以这是修改后的文件:
setlocal enabledelayedexpansion
%mysql% -u %USER% -p%PASSWORD% -B -s -e"show databases" > %backupdir%mysqldblist.tmp
FOR /F %%D IN (%backupdir%mysqldblist.tmp) DO (
set DONTBACKUP=NOTHING
ECHO Creating backup for database ''%%D''
if [%%D]==[information_schema] set DONTBACKUP=TRUE
if [%%D]==[mysql] set DONTBACKUP=TRUE
if [%%D]==[performance_schema] set DONTBACKUP=TRUE
if [%%D]==[test] set DONTBACKUP=TRUE
PAUSE
IF not [!DONTBACKUP!]==[TRUE] %mysqldump% -u %USER% -p%PASSWORD% --result-file="%backupdir%%%D_%mydate%.sql" "%%D"
PAUSE
)