如何对多维数组的子集求和

Question

我无法对多维数组子集中的所有值求和？？

_sum = 总和（的 _valores[_i，_x，_quadrado，*]）;

我知道我可以对一维数组
求和例如_sum = 总和（的 _arraName[*]）;

法典：：

data teste;
    array _quadros{3,3,9} _temporary_;
    array _valores{3,3,9,9} _temporary_;
    /*Zera todos os valores*/
    do _i = 1 to 9;
        do _z = 1 to 3;
            do _t = 1 to 3;
                do _x = 1 to 9;
                    _valores[_z,_t,_i,_x] = 1;
                end;
            end;
        end;
    end;
    do _quadrado = 1 to 9;
        do _i = 1 to 3;
            do _x = 1 to 3;
                _sum = sum(of _valores[_i,_x,_quadrado,*]);
                put _sum =;
            end;
        end;
    end;
run;

错误：：

_sum = 总和（的 _valores[_i，_x，_quadrado，*]）;

错误 386-185：期望算术表达式。

错误 200-322：无法识别该符号，将被忽略。

错误

76-322：语法错误，语句将被忽略。

Answer 1

我认为你不能用sum函数做到这一点。 你可以自己写来做。

proc fcmp outlib=work.fns.fns;
function sumslice4(inArr[*,*,*,*],a,b,c,d) ;
    _1 = dim(inArr,1);
    _2 = dim(inArr,2);
    _3 = dim(inArr,3);
    _4 = dim(inArr,4);
    _s = 0;
    do i=1 to _1;
        do j=1 to _2;
            do k=1 to _3;
                do l=1 to _4;
                    if (a = i or missing(a)) and
                       (b = j or missing(b)) and
                       (c = k or missing(c)) and
                       (d = l or missing(d)) then
                        _s = sum(_s,inArr[i,j,k,l]) ;
                end;
            end;
        end;
    end;
    return (_s);
endsub;
run;
quit;

这将创建一个函数sumslice4()，该函数采用 4 维数组和一系列索引。 指定要求和的索引。 （可选）输入缺失的 . 以指定完整索引。

下面是一个示例测试：

options cmplib=work.fns;
data test;
    array _values{3,3,9,9} _temporary_;
    do _i = 1 to 9;
        do _z = 1 to 3;
            do _t = 1 to 3;
                do _x = 1 to 9;
                    _values[_z,_t,_i,_x] = 1;
                end;
            end;
        end;
    end;
x = sumslice4(_values,1,1,.,.);
put x=;
x = sumslice4(_values,1,1,1,.);
put x=;
x = sumslice4(_values,1,1,1,1);
put x=;
x = sumslice4(_values,.,1,1,1);
put x=;
run;

我得到：

x=81
x=9
x=1
x=3

这应该是你所期望的。

Answer 2

改为规范化数据并使用PROC SUMMARY 。

* generate test data ;
data test;
  do i = 1 to 9;
    do z = 1 to 3;
      do t = 1 to 3;
        do x = 1 to 9;
          valores = 1;
          output;
        end;
      end;
    end;
  end;
run;
* Sum across last dimension ;
proc summary data=test nway ;
  class i z t ;
  var valores ;
  output out=want sum= ;
run;