用div包裹两个值大于0的节点

Question

我需要用xslt 转换以下xml

<item>0</item>
<item>1</item>
<item>2</item>
<item>3</item>
<item>0</item>
<item>6</item>

转换为以下html

<div>
  <i>1</i> 
  <i>2</i>
</div>
<div>
  <i>3</i> 
  <i>6</i>
</div>

换句话说，删除值为0的节点，并用一个div 包裹每2个节点

Answer 1

我会这样做：

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="1.0"> 
<xsl:param name="value" select="0"/>
<xsl:strip-space elements="*"/>
<xsl:output indent="yes"/>
<xsl:template match="@* | node()">
  <xsl:copy>
    <xsl:apply-templates select="@* | node()"/>
  </xsl:copy>
</xsl:template>
<xsl:template match="root">
  <xsl:copy>
    <xsl:apply-templates select="item[not(. = $value)][position() mod 2 = 1]" mode="group"/>
  </xsl:copy>
</xsl:template>
<xsl:template match="item" mode="group">
  <div>
    <xsl:apply-templates select=". | following-sibling::item[not(. = $value)][1]"/>
  </div>
</xsl:template>
</xsl:stylesheet>

则输入为

<root>
<item>0</item>
<item>1</item>
<item>2</item>
<item>3</item>
<item>0</item>
<item>6</item>
</root>

你得到的结果

<root>
   <div>
      <item>1</item>
      <item>2</item>
   </div>
   <div>
      <item>3</item>
      <item>6</item>
   </div>
</root>

如果您还想将item转换为i元素，只需添加模板

<xsl:template match="item">
  <i>
    <xsl:apply-templates/>
  </i>
</xsl:template>

在样式表中。