Perl Tkx：如何将变量作为参数传递给按钮的回调

Question

给定以下Perl/Tkx代码片段:

@itemList = ({'attrib1' => 'name1', 'attrib2' => 'value1'},
             {'attrib1' => 'name2', 'attrib2' => 'value2'});
$row = 0;
foreach $item (@itemList) {
  push(@btn_list, new_ttk__button(-text => $item->{'attrib1'}, -command => sub {do_something($item->{'attrib2'});}));
  $btn_list[-1]->g_grid(-column => 0, -row => $row);
  $row++;
}

(在实际程序中，@itemList是从用户可编辑的配置文件中填充的)

我确实看到两个标签为'name1'和'name2'的按钮。但是当我点击任何一个按钮似乎是传递给回调的参数总是$itemList[1]->{'attrib2'};即。@itemList数组最后一个元素的'attrib2'。我想让第一个按钮称为do_something($itemList[0]->{'attrib2'}，第二个按钮称为do_something($itemList[1]->{'attrib2'}。

我做错了什么，请和谢谢你?

Answer 1

您已经遇到了Perl中for循环的一个微妙特性。首先是解决方案:在for循环中使用my。然后$item将能够在稍后在循环中声明的匿名子中创建一个适当的闭包。

for my $item (@itemlist) {
    push(@btn_list, new_ttk__button(
                       -text => $item->{'attrib1'}, 
                       -command => sub {do_something($item->{'attrib2'});}));
    $btn_list[-1]->g_grid(-column => 0, -row => $row);
    $row++;
}

进一步解释:Perl隐式地本地化了for循环的subject变量。如果在for循环中不使用my，则循环将使用包变量的本地化版本。这使得你的代码相当于:

package main;
$main::item = undef;
@itemList = ({'attrib1' => 'name1', 'attrib2' => 'value1'},
             {'attrib1' => 'name2', 'attrib2' => 'value2'});
$row = 0;
foreach (@itemList) {
    local $main::item = $_;
    push(@btn_list, new_ttk__button(
        -text => $main::item->{'attrib1'},
        -command => sub {do_something($main::item->{'attrib2'});}));
    $btn_list[-1]->g_grid(-column => 0, -row => $row);
    $row++;
}
# at the end of the loop, value of $main::item restored to  undef

您的匿名子程序仍然引用$main::item包变量，无论这些子程序被调用时该变量的值是什么，都可能是undef。

短解:use strict

额外的概念。试着猜测下面的程序输出:

@foo = ( { foo => 'abc', bar => 123 },
         { foo => 'def', bar => 456 } );
my @fn;
foreach $foo (@foo) {
    push @fn, sub { "42" . $foo->{bar} . "n" };
}
foreach my $foo (@foo) {
    push @fn, sub { "19" . $foo->{foo} . "n" };
}
print $_->() for @fn;

答案如下:

42
42
19abc
19def