使用Perl删除整个Reg目录

Question

我想使用perl命令删除Windows Machine中的注册表。我该怎么做。我尝试了一些来自互联网的命令，它正在执行，但没有删除请提供帮助！！以下代码执行，但不会删除Reg Key

use warnings;
use strict;
use Win32::TieRegistry( Delimiter=>"/", ArrayValues=>0 );
my $myway= delete $Registry->{"HKEY_LOCAL_MACHINE/SOFTWARE/Keypath"};
print "Done";

Answer 1

首先，您需要正确的权限来删除注册表项(尝试使用管理员权限从CMD运行Perl脚本(，其次，根据文档，您只能删除不包含任何子项的注册表项：

您可以使用Perl删除函数从注册表中删除值键或删除子键，只要该子键不包含的子键它自己。

第三，即使您使用管理员权限运行，仍然可能有无法删除的密钥，请参阅此问答；A了解更多信息。

因此，如果你想删除整个子树，你需要在树中自下而上迭代，并分别删除每个子键。这里有一个例子：

use feature qw(say);
use warnings;
use strict;
use Data::Dumper qw(Dumper);
use Win32::RunAsAdmin qw(force);
use Win32API::Registry qw(regLastError KEY_READ KEY_WRITE);
use Win32::TieRegistry( Delimiter=>"/", ArrayValues=>0 );
{
# Choose the top root node that should be deleted
# Note: This and all its subkeys will be deleted from the registry.
# Note: Will only succeed if you have permission to write to each sub key
my $top_key_name = "HKEY_CLASSES_ROOT/Directory/Background/shell/Foo";
my $tree = $Registry->Open(
$top_key_name,  
{ Access=>KEY_READ()|KEY_WRITE(), Delimiter=>"/" } 
);
die "Could not open key $top_key_name: $^E" if !defined $tree;
delete_subtree( $tree, my $level = 0);
}
sub delete_subtree {
my ($tree, $level) = @_;
my $path = $tree->Path();
my @subkeys = $tree->SubKeyNames();
for my $name (@subkeys) {
my $subtree = $tree->{$name."/"};
if (!defined $subtree) {
die "Cannot access subkey $name for $path: " . regLastError() . ". Abort.";
}
if (ref $subtree) {
delete_subtree($subtree, $level + 1);
}
else {
die "Subkey $name for $path is not a hash ref. Abort.";
}
}

# assuming the previous recursive code has deleted all sub keys of the 
# current key, we can now try delete this key
say "Trying to delete $path ..";
my $res = delete $Registry->{$path};
if (!defined $res) {
die "..Failed to delete key : $^E";
}
else {
say "  -> success";
}
}